reserve T for TopStruct;
reserve GX for TopSpace;

theorem Th15:
  for A being Subset of T, p being set st p in the carrier of T
  holds p in Cl A iff for C being Subset of T st C is closed holds (A c= C
  implies p in C)
proof
  let A be Subset of T, p be set such that
A1: p in the carrier of T;
A2: now
    assume
A3: for C being Subset of T st C is closed holds (A c= C implies p in C);
    for G being Subset of T st G is open holds (p in G implies A meets G)
    proof
      let G be Subset of T such that
A4:   G is open;
      [#]T \ ([#]T \ G) = G by Th3;
      then [#]T \ G is closed by A4;
      then A c= G` implies p in [#]T \ G by A3;
      hence thesis by SUBSET_1:23,XBOOLE_0:def 5;
    end;
    hence p in Cl A by A1,Def7;
  end;
  now
    assume
A5: p in Cl A;
    let C be Subset of T;
    assume C is closed;
    then [#]T \ C is open;
    then p in [#]T \ C implies A meets ([#]T \ C) by A5,Def7;
    then A c= ([#]T \ C)` implies (p in C or not p in [#]T) by SUBSET_1:23
,XBOOLE_0:def 5;
    hence A c= C implies p in C by A1,Th3;
  end;
  hence thesis by A2;
end;
