reserve X for set,
        n,m,k for Nat,
        K for Field,
        f for n-element real-valued FinSequence,
        M for Matrix of n,m,F_Real;

theorem Th16:
  for a be Real,
      x,y be Element of REAL-NS(n),
      x0,y0 be Element of RealVectSpace(Seg n)
    st x = x0 & y = y0
  holds
      the carrier of REAL-NS(n) = the carrier of RealVectSpace(Seg n)
    & 0. REAL-NS(n) = 0.RealVectSpace(Seg n)
    & x + y = x0 + y0
    & a * x = a * x0
    & -x = -x0
    & x - y = x0 - y0
  proof
    let a be Real,
    x,y be Element of REAL-NS(n),
    x0,y0 be Element of RealVectSpace(Seg n);

    assume
    A1: x = x0 & y = y0;

    A2: the RLSStruct of REAL-NS(n) = RealVectSpace(Seg n) by Th15;
    set V = REAL-NS(n);
    set W = RealVectSpace(Seg n);

    thus the carrier of REAL-NS (n) = the carrier of RealVectSpace(Seg n)
      &
    0. REAL-NS (n) = 0.RealVectSpace(Seg n) by A2;

    thus x + y = x0 + y0 by A1,A2;
    thus a * x = a * x0 by A1,A2;

    thus
    -x = (-1) * x by RLVECT_1:16
    .= (-1) * x0 by A1,A2
    .= -x0 by RLVECT_1:16;

    -y = (-1) * y by RLVECT_1:16
    .= (-1) * y0 by A1,A2
    .= -y0 by RLVECT_1:16;

    hence x-y = x0 - y0 by A1,A2;
  end;
