 reserve L for non empty LattStr;
 reserve v64,v65,v66,v67,v103,v3,v102,v101,v100,v2,v1,v0 for Element of L;
 reserve L for distributive join-commutative meet-commutative
   non empty LattStr;
 reserve v0,v1,v2 for Element of L;
 reserve L for non empty LattStr;
 reserve v103,v3,v102,v101,v100,v2,v1,v0 for Element of L;

theorem CombinedMcKenzie:
  L is Lattice iff
    L is satisfying_4_McKenzie_axioms
  proof
    thus L is Lattice implies
      L is satisfying_4_McKenzie_axioms
    proof
      assume A1: L is Lattice;
C1:   for v1,v0 holds (v0"/\"(v0"\/"v1))=v0 by A1,LATTICES:def 9;
      for v1,v0 holds v0"\/"(v0"/\"v1)=v0
      proof
        let v1,v0;
A2:     L is join-commutative meet-commutative meet-absorbing by A1; then
        v0"\/"(v0"/\"v1) = (v0"/\"v1)"\/"v0
            .=(v1"/\"v0)"\/"v0 by A2
            .=v0 by A2;
        hence thesis;
      end; then
      L is satisfying_McKenzie_1 &
      L is satisfying_McKenzie_2 &
      L is satisfying_McKenzie_3 &
      L is satisfying_McKenzie_4 by AuxiliaryMcKenzie,A1,C1;
      hence thesis;
    end;
    assume L is satisfying_4_McKenzie_axioms; then
b1: L is satisfying_McKenzie_1 &
    L is satisfying_McKenzie_2 &
    L is satisfying_McKenzie_3 &
    L is satisfying_McKenzie_4; then
B1: (for v1,v0 being Element of L holds v0"/\"(v0"\/"v1)=v0) &
    (for v1,v0 being Element of L holds (v0"\/"(v0"/\"v1))=v0) &
    L is join-commutative meet-commutative meet-associative join-associative
      by MainMcKenzie;
B2: for v0,v1 being Element of L holds (v1 "/\" v0) "\/" v0 = v0
    proof
      let v0,v1;
      (v1 "/\" v0) "\/" v0 = v0 "\/" (v1 "/\" v0) by B1
          .= v0 "\/" (v0 "/\" v1) by B1
          .= v0 by b1,MainMcKenzie;
      hence thesis;
    end;
    L is meet-absorbing join-absorbing by b1,B2,MainMcKenzie;
    hence thesis by B1;
  end;
