reserve F for total
  NAT-defined (the InstructionsF of SCM)-valued Function;

theorem
  for F being total
   NAT-defined (the InstructionsF of SCM)-valued Function
    st <%dl.0 := dl.1%>^<%halt SCM%> c= F
  for i1, i2 being Integer,
      s being 0-started State-consisting of <%i1,i2%>
   holds F halts_on s & LifeSpan(F,s) = 1 & (Result(F,s)).dl.0 = i2 &
  for d being Data-Location st d<>dl.0
   holds (Result(F,s)).d = s.d
proof
  let F be total
   NAT-defined (the InstructionsF of SCM)-valued Function such that
A1: <%dl.0 := dl.1%>^<%halt SCM%> c= F;
  let i1, i2 be Integer,
    s be 0-started State-consisting of <%i1,i2%>;
  set s1 = Comput(F,s,0+1);
A2: s.dl.1 = i2 by Th2;
A3: IC s = 0 & s = Comput(F,s,0) by EXTPRO_1:2,MEMSTR_0:def 11;
A4: F.0 = dl.0 := dl.1 by A1,Th3;
  then
A5: IC s1 = 0+1 by A3,Th4;
A6: F.1 = halt SCM by A1,Th3;
  hence F halts_on s by A5,EXTPRO_1:30;
  thus LifeSpan(F,s) = 1 by A6,A3,A5,EXTPRO_1:33;
  s1.dl.0 = s.dl.1 by A4,A3,Th4;
  hence (Result(F,s)).dl.0 = i2 by A6,A2,A5,EXTPRO_1:7;
  let d be Data-Location;
  assume
A7: d<>dl.0;
  thus (Result(F,s)).d = s1.d by A6,A5,EXTPRO_1:7
    .= s.d by A4,A3,A7,Th4;
end;
