reserve A,A1,A2,B,B1,B2,C,O for Ordinal,
      R,S for Relation,
      a,b,c,o,l,r for object;

theorem Th15:
    R /\ [:BeforeGames A,BeforeGames A:] =
    S /\ [:BeforeGames A,BeforeGames A:]
  implies ClosedProd(R,A,B) = ClosedProd(S,A,B)
proof
  assume A1: R /\ [:BeforeGames A,BeforeGames A:] =
  S /\ [:BeforeGames A,BeforeGames A:];
  A2:Day(R,A) = Day(S,A) by A1,Th10;
  let x,y be object;
  thus [x,y] in ClosedProd(R,A,B) implies [x,y] in ClosedProd(S,A,B)
  proof
    assume A3:[x,y] in ClosedProd(R,A,B);
    A4: x in Day(R,A) & y in Day(R,A) by A3,ZFMISC_1:87;
    A5: born(R,x) = born(S,x) & born(R,y) = born(S,y) by A1,A4,Th11;
    (born(R,x) in A & born(R,y) in A) or
    (born(R,x) = A & born(R,y) c= B) or
    (born(R,x) c= B & born(R,y) = A) by A3,A4,Def10;
    hence thesis by A4,A2,A5,Def10;
  end;
  assume A6:[x,y] in ClosedProd(S,A,B);
  A7: x in Day(S,A) & y in Day(S,A) by A6,ZFMISC_1:87;
  A8: born(R,x) = born(S,x) & born(R,y) = born(S,y) by A1,A7,Th11;
  (born(S,x) in A & born(S,y) in A) or
  (born(S,x) = A & born(S,y) c= B) or
  (born(S,x) c= B & born(S,y) = A) by A6,A7,Def10;
  hence thesis by A7,A2,A8,Def10;
end;
