
theorem  :: p. 100, Remark 1.4 (v)
  for T being Scott TopLattice, S being Subset of T
  holds S is open iff S is upper property(S)
proof
  let T be Scott TopLattice, S be Subset of T;
  hereby
    assume
A1: S is open;
    hence
A2: S is upper by Def4;
    thus S is property(S)
    proof
      let D be non empty directed Subset of T such that
A3:   sup D in S;
      S is inaccessible by A1,Def4;
      then S meets D by A3;
      then consider y being object such that
A4:   y in S and
A5:   y in D by XBOOLE_0:3;
      reconsider y as Element of T by A4;
      take y;
      thus thesis by A2,A4,A5;
    end;
  end;
  assume that
A6: S is upper and
A7: S is property(S);
  S is inaccessible
  proof
    let D be non empty directed Subset of T;
    assume sup D in S;
    then consider y being Element of T such that
A8: y in D and
A9: for x being Element of T st x in D & x >= y holds x in S by A7;
    y >= y by YELLOW_0:def 1;
    then y in S by A8,A9;
    hence thesis by A8,XBOOLE_0:3;
  end;
  hence thesis by A6,Def4;
end;
