reserve V for Universe,
  a,b,x,y,z,x9,y9 for Element of V,
  X for Subclass of V,
  o,p,q,r,s,t,u,a1,a2,a3,A,B,C,D for set,
  K,L,M for Ordinal,
  n for Element of omega,
  fs for finite Subset of omega,
  e,g,h for Function,
  E for non empty set,
  f for Function of VAR,E,
  k,k1 for Element of NAT,
  v1,v2,v3 for Element of VAR,
  H,H9 for ZF-formula;

theorem Th15:
  for n st X is closed_wrt_A1-A7 & a in X & a c= X & y in Funcs(fs
  ,a) holds {{[n,x]} \/ y: x in a} in X
proof
  let n;
  assume that
A1: X is closed_wrt_A1-A7 and
A2: a in X and
A3: a c= X & y in Funcs(fs,a);
  set Z={{[n,x]} \/ y: x in a};
  set s={y};
  set Y={{[n,x]} \/ z: x in a & z in s};
A4: Y=Z
  proof
    thus Y c= Z
    proof
      let p be object;
      assume p in Y;
      then consider x,z such that
A5:   p={[n,x]} \/ z & x in a and
A6:   z in s;
      z=y by A6,TARSKI:def 1;
      hence thesis by A5;
    end;
    let p be object;
    assume p in Z;
    then
A7: ex x st p={[n,x]} \/ y & x in a;
    y in s by TARSKI:def 1;
    hence thesis by A7;
  end;
  y in X by A1,A3,Th14;
  then {y} in X by A1,Th2;
  hence thesis by A1,A2,A4,Th12;
end;
