
theorem N2POWINPOLY:
  for x be Nat st 1 < x holds
  not ex N,c be Nat st
  for n be Nat st N <= n holds 2 to_power n <= c * (n to_power x)
  proof
    let x be Nat;
    assume AS1:1 < x;
    assume ASC:ex N,c be Nat st
    for n be Nat st N <= n holds
    2 to_power n <= c * (n to_power x);
    consider N be Nat such that
    ASC1: ex c be Nat st
    for n be Nat st N <= n holds
    2 to_power n <= c * (n to_power x) by ASC;
    N <> 0
    proof
      assume N=0;then
      consider c be Nat such that LNT:
      for n be Nat st 0 <= n holds
      2 to_power n <= c * ( n to_power x) by ASC1;
      2 to_power 0 <= c * ( 0 to_power x) by LNT;then
      2 to_power 0 <= c * 0 by POWER:42,AS1;
      hence contradiction by POWER:24;
    end;
    then
    LPNN2:0 < N;
    consider c be Nat such that
    ASC2: for n be Nat st N <= n holds
    2 to_power n <= c * (n to_power x) by ASC1;
    ex n be Element of NAT st N <= n & 0 < n - x/4
    proof
      now per cases;
        case AC1: x/4 < N;
          reconsider n = N+1 as Element of NAT;
          take n;
          thus N <= n by INT_1:6;then
          x/4 < n by AC1,XXREAL_0:2;
          hence 0 < n- x/4 by XREAL_1:50;
        end;
        case AC2: N <= x/4;
          reconsider n = [/x/4 \] + 1 as Integer;
          AC33: x/4 <= [/ x/4 \] by INT_1:def 7;then
          AC3:x/4 +0 < [/ x/4 \] +1 by XREAL_1:8;
          reconsider n as Element of NAT by INT_1:3,AC33;
          take n;
          thus 0 < n -x/4 by AC3,XREAL_1:50;
          thus N <= n by AC3,AC2,XXREAL_0:2;
        end;
      end;
      hence thesis;
    end;then
    consider n be Element of NAT such that
    ASC3: N <= n & 0 < n - x/4;
    XC1: 2 to_power n <= c * ( n to_power x) by ASC2,ASC3;
    ZZ1:0 <n & 1 <x by AS1,ASC3;
    TEZ1: 0 <c
    proof
      assume not 0 < c; then
      2 to_power n <= 0 * (n to_power x) by XC1;
      hence contradiction by POWER:34;
    end;
    ASC22: for k be Nat st 1 <= k holds
    2 to_power (k*n) <= c * ((k*n) to_power x)
    proof
      let k be Nat;
      assume 1 <= k;then
      1*N <= k*n by ASC3,XREAL_1:66;
      hence thesis by ASC2;
    end;
    HCL1:
    for k be Nat st 1 <= k holds
    k*n <= log(2, c) + x*log(2, k) + x*log(2,n)
    proof
      let k be Nat;
      assume ASK: 1 <= k; then
      L1: 2 to_power (k*n) <= c * ( (k*n) to_power x) by ASC22;
      L3:0 < (k*n) to_power x by POWER:34,LPNN2,ASC3,ASK;
      0 < 2 to_power(k*n) by POWER:34;then
      log (2,2 to_power (k*n)) <= log(2, c * ( (k*n) to_power x))
      by L1,CPOWER57;then
      (k*n)* log (2,2) <= log(2, c * ( (k*n) to_power x))
      by POWER:55;then
      (k*n)* 1 <= log(2, c * ( (k*n) to_power x)) by POWER:52;then
      k*n <= log(2, c ) + log(2, (k*n) to_power x)
      by POWER:53,TEZ1,L3;then
      k*n <= log(2, c ) + x*log(2, k*n) by POWER:55,LPNN2,ASC3,ASK; then
      k*n <= log(2, c ) + x*(log(2, k) + log(2,n)) by POWER:53,ASK,ZZ1;
      hence k*n <= log(2, c ) + x*log(2, k) + x*log(2,n);
    end;
    consider Z be Element of NAT such that
    HCL2: for k be Nat st Z <= k holds 4 < k/log(2,k) by LMC31HC;
    HEXK:
    ex k be Nat st Z <= k &
    (log(2, c) + x*log(2,n))/ (n - x/4) <= k
    proof
      now per cases;
        case AC1: (log(2, c ) + x*log(2,n))/ (n - x/4) < Z;
          reconsider k = Z+1 as Element of NAT;
          take k;
          thus Z <= k by INT_1:6;
          hence (log(2, c ) + x*log(2,n))/ (n - x/4) < k by AC1,XXREAL_0:2;
        end;
        case AC2: Z <= (log(2, c ) + x*log(2,n))/ (n - x/4);
          reconsider
          k = [/ (log(2, c) + x*log(2,n))/ (n - x/4) \] + 1 as Integer;
          AC3P:(log(2, c) + x*log(2,n))/ (n - x/4)
          <= [/ (log(2, c) + x*log(2,n))/ (n - x/4) \] by INT_1:def 7;then
          AC3:(log(2, c) + x*log(2,n))/ (n - x/4) +0
          <= [/ (log(2, c) + x*log(2,n))/ (n - x/4) \] +1 by XREAL_1:8;
          reconsider k as Element of NAT by AC3P,INT_1:3,AC2;
          take k;
          thus (log(2, c) + x*log(2,n))/ (n - x/4) <= k by AC3;
          thus Z <= k by AC3,AC2,XXREAL_0:2;
        end;
      end;
      hence thesis;
    end;
    ex k be Nat st Z <= k &
    (log(2, c ) + x*log(2,n))/ (n - x/4) <= k & 1 < k
    proof
      consider k be Nat such that HEXK2: Z <= k &
      (log(2, c ) + x*log(2,n))/ (n - x/4) <= k by HEXK;
      reconsider a = k+2 as Nat;
      take a;
      CC1:0 + 2 <= k+2 by XREAL_1:6;
      k <= a by NAT_1:11;
      hence thesis by CC1,XXREAL_0:2,HEXK2;
    end; then
    consider k be Nat such that
    HCL3: Z <= k & 1 <k &
    (log(2, c ) + x*log(2,n))/ (n - x/4) <= k;
    FF0:(log(2, c ) + x*log(2,n))/ (n - x/4)
    * (n - x/4) <= k *(n - x/4) by HCL3,ASC3,XREAL_1:64;
    HCL4: 4 < k/log(2,k) by HCL2,HCL3;
    HCL7:
    k*n <= log(2, c ) + x*log(2, k) + x*log(2,n) by HCL1,HCL3;
    HCL8: 0 < log(2,k) by ENTROPY1:4,HCL3; then
    4*log(2,k) < k/log(2,k) *log(2,k) by HCL4,XREAL_1:68;then
    4*log(2,k) < k*log(2,k) /log(2,k) by XCMPLX_1:74;then
    4*log(2,k) < k*(log(2,k) /log(2,k)) by XCMPLX_1:74;then
    4*log(2,k) < k*(1) by XCMPLX_1:60,HCL8;then
    log(2,k)*4*x < k*x by XREAL_1:68,AS1; then
    log(2,k)*x*4/4 < k*x/4 by XREAL_1:74; then
    k*n - k*x/4 < log(2, c) + x*log(2, k) + x*log(2,n) -x*log(2,k)
    by HCL7,XREAL_1:15;
    hence contradiction by FF0,XCMPLX_1:87,ASC3;
  end;
