reserve k,m,n for Nat;
reserve R for commutative Ring,
        p,q for Polynomial of R,
        z0,z1 for Element of R;

theorem
  for im being imaginary Element of F_Complex,
      r being real Element of F_Complex st n is even holds
    even_part (<% im,r %>`^n) is real &
    odd_part (<% im,r %>`^n) is imaginary
proof
  let im be imaginary Element of FC,
      r be real Element of FC;
  assume A1: n is even;
  set pC=power FC;
  set IRn = <% im,r %>`^n;
  thus even_part (IRn) is real
  proof
    let k be Nat;
    per cases;
      suppose k is odd;
        hence thesis by HURWITZ2:def 1;
      end;
      suppose A2: k is even;
        A3: IRn.k = (n choose k) * ((r|^k) * (im|^(n-'k))) by Th13;
        n-'k = n-k or n-'k =0 by XREAL_0:def 2;
        hence thesis by HURWITZ2:def 1,A3,A1,A2;
      end;
  end;
  thus odd_part IRn is imaginary
  proof
    let k be Nat;
    per cases;
      suppose k is even;
        hence thesis by HURWITZ2:def 2;
      end;
      suppose A4:k is odd;
        A5: IRn.k = (n choose k) * ((r|^k) * (im|^(n-'k))) by Th13;
        per cases;
          suppose k <=n;
            then n-'k = n-k by XREAL_1:233;
            hence thesis by HURWITZ2:def 2,A5,A1,A4;
          end;
          suppose k >n;
            then n choose k = 0 by NEWTON:def 3;
            hence thesis by A4,A5,HURWITZ2:def 2;
          end;
      end;
  end;
end;
