reserve Y for non empty set;
reserve B for Subset of Y;

theorem Th15:
  for a,b being Function of Y,BOOLEAN holds (a 'imp' b)=I_el
  (Y) iff a '<' b
proof
  let a,b be Function of Y,BOOLEAN;
A1: for a,b being Function of Y,BOOLEAN holds a '<' b implies (a 'imp'
  b)=I_el(Y)
  proof
    let a,b be Function of Y,BOOLEAN;
    assume
A2: a '<' b;
A3: for x being Element of Y holds ('not' a.x) 'or' b.x = TRUE
    proof
      let x be Element of Y;
      a.x = FALSE & b.x = FALSE or a.x = FALSE & b.x = TRUE or a.x = TRUE
      & b.x = TRUE by A2,XBOOLEAN:def 3;
      hence thesis;
    end;
      let x be Element of Y;
      (a 'imp' b).x = ('not' a.x) 'or' b.x & (I_el Y).x= TRUE by Def8,Def11;
      hence thesis by A3;
  end;
  for a,b being Function of Y,BOOLEAN holds (a 'imp' b)=I_el(Y)
  implies a '<' b
  proof
    let a,b be Function of Y,BOOLEAN;
    assume
A4: (a 'imp' b)=I_el(Y);
A5: for x being Element of Y holds ('not' a.x) 'or' b.x = TRUE
    proof
      let x be Element of Y;
      (a 'imp' b).x=('not' a.x) 'or' b.x by Def8;
      hence thesis by A4,Def11;
    end;
    for x being Element of Y holds a.x = FALSE & b.x = FALSE or a.x =
    FALSE & b.x = TRUE or a.x = TRUE & b.x = TRUE
    proof
      let x be Element of Y;
A6:  ('not' a.x) = TRUE & b.x = FALSE or ('not' a.x) = TRUE & b.x = TRUE
or ('not' a.x) = FALSE & b.x = FALSE or ('not' a.x) = FALSE & b.x = TRUE by
XBOOLEAN:def 3;
      ('not' a.x) 'or' b.x = TRUE by A5;
      hence thesis by A6;
    end;
    then for x being Element of Y st a.x= TRUE holds b.x=TRUE;
    hence thesis;
  end;
  hence thesis by A1;
end;
