reserve x, x1, x2, y, z, X9 for set,
  X, Y for finite set,
  n, k, m for Nat,
  f for Function;

theorem Th15:
 for x,y being object holds
  x<>y implies card Choose(X,k,x,y)=card X choose k
proof let x,y be object;
  defpred P[Nat] means for k,X st k+ card X <= $1 holds card Choose
  (X,k,x,y)=(card X) choose k;
  assume
A1: x<>y;
A2: for n st P[n] holds P[n+1]
  proof
    let n such that
A3: P[n];
    let k,X such that
A4: k+ card X <= n+1;
    per cases by A4,XXREAL_0:1;
    suppose
      k+ card X < n+1;
      then k+card X<=n by NAT_1:13;
      hence thesis by A3;
    end;
    suppose
A5:   k+ card X = n+1;
      per cases;
      suppose
A6:     k=0 & card X>=0;
        then card Choose(X,k,x,y)=1 by A1,Th10;
        hence thesis by A6,NEWTON:19;
      end;
      suppose
A7:     k>0 & card X=0;
        then Choose(X,k,x,y) is empty by Th9;
        hence thesis by A7,NEWTON:def 3;
      end;
      suppose
A8:     k>0 & card X>0;
        then reconsider cXz=(card X)-1 as Element of NAT by NAT_1:20;
        reconsider k1=k-1 as Element of NAT by A8,NAT_1:20;
        consider z being object such that
A9:     z in X by A8,CARD_1:27,XBOOLE_0:def 1;
        set Xz=X\{z};
        z in {z} by TARSKI:def 1;
        then
A10:    not z in Xz by XBOOLE_0:def 5;
        Xz\/{z}=X by A9,ZFMISC_1:116;
        then
A11:    card Choose(X,k1+1,x,y)= card Choose(Xz,k1+1,x,y)+ card Choose(Xz
        ,k1,x, y) by A1,A10,Th14;
        card X=cXz+1;
        then
A12:    card Xz=cXz by A9,STIRL2_1:55;
        cXz< cXz+1 by NAT_1:13;
        then
A13:    card Xz < card X by A9,STIRL2_1:55;
        then k+card Xz<n+1 by A5,XREAL_1:8;
        then k+card Xz<=n by NAT_1:13;
        then
A14:    card Choose(Xz,k1+1,x,y)=(card Xz) choose (k1+1) by A3;
        k1<k1+1 by NAT_1:13;
        then k1+card Xz<n+1 by A5,A13,XREAL_1:8;
        then k1+card Xz<=n by NAT_1:13;
        then
A15:    card Choose(Xz,k1,x,y)=(card Xz) choose k1 by A3;
        card X=cXz+1;
        hence thesis by A14,A15,A11,A12,NEWTON:22;
      end;
    end;
  end;
A16: P[0]
  proof
    let k,X;
A17:  0 choose 0 = 1 by NEWTON:19;
    assume k+ card X <= 0;
    then k+ card X =0 & card X=0;
    hence thesis by A1,Th10,A17;
  end;
  for n holds P[n] from NAT_1:sch 2(A16,A2);
  then P[k+card X];
  hence thesis;
end;
