reserve            x for object,
               X,Y,Z for set,
         i,j,k,l,m,n for Nat,
                 r,s for Real,
                  no for Element of OrderedNAT,
                   A for Subset of [:NAT,NAT:];

theorem Th15:
  proj2 A = {y where y is Element of NAT:
    ex x being Element of NAT st [x,y] in A}
  proof
    set A2 = {y where y is Element of NAT: ex x being Element of NAT st
              [x,y] in A};
A1: proj2 A c= A2
    proof
      let y be object;
      assume y in proj2 A;
      then consider x be object such that
A2:   [x,y] in A by XTUPLE_0:def 13;
      ex x1,y1 be object st x1 in NAT & y1 in NAT & [x,y] = [x1,y1]
        by A2,ZFMISC_1:def 2;
      then reconsider x,y as Element of NAT by XTUPLE_0:1;
      [x,y] in A & y is Element of NAT by A2;
      hence thesis;
    end;
    A2 c= proj2 A
    proof
      let y be object;
      assume y in A2;
      then ex y1 be Element of NAT st y = y1 & ex x be Element of NAT st
        [x,y1] in A;
      hence thesis by XTUPLE_0:def 13;
    end;
    hence thesis by A1;
  end;
