reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem
  rng seq c= dom (h|X) & h"{0}={} implies ((h^)|X)/*seq = ((h|X)/*seq)"
proof
  assume that
A1: rng seq c= dom (h|X) and
A2: h"{0}={};
  now
    let x be object;
    assume x in rng seq;
    then x in dom (h|X) by A1;
    then
A3: x in dom h /\ X by RELAT_1:61;
    then x in dom h \ h"{0c} by A2,XBOOLE_0:def 4;
    then
A4: x in dom (h^) by CFUNCT_1:def 2;
    x in X by A3,XBOOLE_0:def 4;
    then x in dom (h^) /\ X by A4,XBOOLE_0:def 4;
    hence x in dom ((h^)|X) by RELAT_1:61;
  end;
  then
A5: rng seq c= dom ((h^)|X);
  now
    let n be Element of NAT;
A6: seq.n in rng seq by VALUED_0:28;
    then seq.n in dom (h|X) by A1;
    then
A7: seq.n in dom h /\ X by RELAT_1:61;
    then seq.n in dom h \ h"{0c} by A2,XBOOLE_0:def 4;
    then
A8: seq.n in dom (h^) by CFUNCT_1:def 2;
    seq.n in X by A7,XBOOLE_0:def 4;
    then seq.n in dom (h^) /\ X by A8,XBOOLE_0:def 4;
    then
A9: seq.n in dom((h^)|X) by RELAT_1:61;
    thus (((h^)|X)/*seq).n = ((h^)|X)/.(seq.n) by A5,FUNCT_2:109
      .= (h^)/.(seq.n) by A9,PARTFUN2:15
      .= (h/.(seq.n))" by A8,CFUNCT_1:def 2
      .= ((h|X)/.(seq.n))" by A1,A6,PARTFUN2:15
      .= (((h|X)/*seq).n)" by A1,FUNCT_2:109
      .= (((h|X)/*seq)").n by VALUED_1:10;
  end;
  hence thesis by FUNCT_2:63;
end;
