reserve W,X,Y,Z for set,
  f,g for Function,
  a,x,y,z for set;
reserve u,v for Element of Tarski-Class(X),
  A,B,C for Ordinal,
  L for Sequence;

theorem Th16:
  A c= B implies Tarski-Class(X,A) c= Tarski-Class(X,B)
proof
  defpred OnP[Ordinal] means
  A c= $1 implies Tarski-Class(X,A) c= Tarski-Class(X,$1);
A1: for B st for C st C in B holds OnP[C] holds OnP[B]
  proof
    let B such that
A2: for C st C in B holds OnP[C] and
A3: A c= B;
    let x be object;
    assume
A4: x in Tarski-Class(X,A);
 now
      assume
A5:   A <> B;
then A6:   A in B by ORDINAL1:11,A3,XBOOLE_0:def 8;
A7:   B <> {} by A3,A5;
A8:  now
        given C such that
A9:    B = succ C;
    A c= C & C in B by A6,A9,ORDINAL1:22;
then A10:    Tarski-Class(X,A) c= Tarski-Class(X,C) by A2;
    Tarski-Class(X,C) c= Tarski-Class(X,B) by A9,Th15;
then     Tarski-Class(X,A) c= Tarski-Class(X,B) by A10;
        hence thesis by A4;
      end;
  now
        assume for C holds B <> succ C;
then     Tarski-Class(X,B) = { v : ex C st C in B & v in Tarski-Class(X,C)
        } by A7,Th9,ORDINAL1:29;
        hence thesis by A4,A6;
      end;
      hence thesis by A8;
    end;
    hence thesis by A4;
  end;
 for B holds OnP[B] from ORDINAL1:sch 2(A1);
  hence thesis;
end;
