
theorem Th15: :: Exercise 4.29 (addition)
  for R being RelStr
  st R\~ is well_founded & R is antisymmetric holds R is well_founded
proof
  let R be RelStr such that
A1: R\~ is well_founded and
A2: R is antisymmetric;
  set IR = the InternalRel of R, CR = the carrier of R;
  set IR9 = the InternalRel of R\~;
A3: IR is_antisymmetric_in CR by A2;
A4: IR9 is_well_founded_in CR by A1,WELLFND1:def 2;
  now
    let Y be set such that
A5: Y c= CR and
A6: Y <> {};
    consider a being object such that
A7: a in Y and
A8: IR9-Seg(a) misses Y by A4,A5,A6,WELLORD1:def 3;
A9: IR9-Seg(a) /\ Y = {} by A8,XBOOLE_0:def 7;
    take a;
    thus a in Y by A7;
    now
      assume IR-Seg(a) /\ Y <> {};
      then consider z being object such that
A10:  z in IR-Seg(a) /\ Y by XBOOLE_0:def 1;
A11:  z in IR-Seg(a) by A10,XBOOLE_0:def 4;
A12:  z in Y by A10,XBOOLE_0:def 4;
A13:  z <> a by A11,WELLORD1:1;
A14:  [z,a] in IR by A11,WELLORD1:1;
      then not [a,z] in IR by A3,A5,A7,A12,A13;
      then not [z,a] in IR~ by RELAT_1:def 7;
      then [z,a] in IR \ IR~ by A14,XBOOLE_0:def 5;
      then z in IR9-Seg(a) by A13,WELLORD1:1;
      hence contradiction by A9,A12,XBOOLE_0:def 4;
    end;
    hence IR-Seg(a) misses Y by XBOOLE_0:def 7;
  end;
  then IR is_well_founded_in CR by WELLORD1:def 3;
  hence thesis by WELLFND1:def 2;
end;
