 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;
reserve n for non zero Nat;

theorem
   ex K being Field, x being object st not x in rng(canHom K) &
   x in [#]K /\ [#]Polynom-Ring K
   proof
     set F = the non almost_trivial Field;
     set y = the non trivial Element of F;
     reconsider o = <%0.F,1.F%> as object;
     per cases;
       suppose not o in [#]F; then
         reconsider K = ExField(y,o) as Field by Th7,Th8,Th10,Th9,Th12,Th11;
         take K;
         take x = <%0.K,1.K%>;
         now let n be Element of NAT;
           per cases by NAT_1:23;
             suppose
A1:            n = 0;
               hence <%0.F,1.F%>.n = 0.F by POLYNOM5:38 .= 0.K by Def8
               .= <%0.K,1.K%>.n by A1,POLYNOM5:38;
             end;
             suppose
A2:            n = 1;
               hence <%0.F,1.F%>.n = 1.F by POLYNOM5:38 .= 1.K by Def8
               .= <%0.K,1.K%>.n by A2,POLYNOM5:38;
             end;
             suppose
A3:            n >= 2;
               hence <%0.F,1.F%>.n = 0.F by POLYNOM5:38 .= 0.K by Def8
               .= <%0.K,1.K%>.n by A3,POLYNOM5:38;
             end;
           end; then
A4:        <%0.F,1.F%> = <%0.K,1.K%>; then
           x in [#]K /\ [#]Polynom-Ring K by Th13;
           then
           reconsider x as Element of the carrier of Polynom-Ring K;
A5:        deg x = len x - 1 by HURWITZ:def 2
           .= 2 -1 by POLYNOM5:40;
           now assume x in rng canHom K; then
             consider a being object such that
A6:          a in dom(canHom K) & x = (canHom K).a by FUNCT_1:def 3;
             reconsider a as Element of [#]K by A6;
             deg(a|K) <= 0 by RATFUNC1:def 2;
             hence contradiction by A6,A5,RING_4:def 6;
           end;
           hence thesis by A4,Th13;
         end;
         suppose
A7:        ex a being Element of F st a = <%0.F,1.F%>;
           take F;
           take x = <%0.F,1.F%>;
           2 = len x by POLYNOM5:40; then
A8:        deg x = 2-1 by HURWITZ:def 2;
A9:        x in the carrier of Polynom-Ring F by POLYNOM3:def 10;
           now assume x in rng(canHom F); then
             consider a being object such that
A10:         a in dom(canHom F) & x = (canHom F).a by FUNCT_1:def 3;
             reconsider a as Element of [#]F by A10;
             deg(a|F) <= 0 by RATFUNC1:def 2;
             hence contradiction by A10,A8,RING_4:def 6;
           end;
           hence thesis by A7,A9,XBOOLE_0:def 4;
         end;
       end;
