
theorem
  for n being non zero Nat ex h being Function of FTSS2(n,1),
  FTSL1 n st h is being_homeomorphism
proof
  defpred P[object,object] means [$2,1]=$1;
  let n be non zero Nat;
  set FT1=FTSS2(n,1),FT2= FTSL1 n;
A1: for x be object st x in the carrier of FTSS2(n,1)
ex y be object st y in the carrier of FTSL1 n & P[x,y]
  proof
    let x be object;
A2: FTSL1 n = RelStr(# Seg n,Nbdl1 n #) by FINTOPO4:def 4;
    assume x in the carrier of FTSS2(n,1);
    then consider u,v being object such that
A3: u in Seg n and
A4: v in Seg 1 and
A5: x= [u,v] by ZFMISC_1:def 2;
    reconsider nu=u,nv=v as Nat by A3,A4;
    1<=nv & nv<=1 by A4,FINSEQ_1:1;
    then P[x,nu] by A5,XXREAL_0:1;
    hence thesis by A3,A2;
  end;
  ex f being Function of FTSS2(n,1), FTSL1 n st
for x be object st x in the
  carrier of FTSS2(n,1) holds P[x,f.x] from FUNCT_2:sch 1(A1);
  then consider f being Function of FTSS2(n,1), FTSL1 n such that
A6: for x be object st x in the carrier of FTSS2(n,1) holds P[x,f.x];
A7: FTSL1 n = RelStr(# Seg n,Nbdl1 n #) by FINTOPO4:def 4;
A8: the carrier of FTSL1 n c= rng f
  proof
    let x be object;
    set z=[x,1];
A9: 1 in Seg 1;
    assume x in the carrier of FTSL1 n;
    then
A10: z in the carrier of FTSS2(n,1) by A7,A9,ZFMISC_1:def 2;
    then [f.z,1]=z by A6;
    then
A11: f.z=x by XTUPLE_0:1;
    z in dom f by A10,FUNCT_2:def 1;
    hence thesis by A11,FUNCT_1:def 3;
  end;
A12: for x being Element of FT1 holds f.:U_FT x=Im(the InternalRel of FT2,f. x)
  proof
    let x be Element of FT1;
    consider u,v being object such that
A13: u in Seg n and
A14: v in Seg 1 and
A15: x= [u,v] by ZFMISC_1:def 2;
A16: f.:U_FT x c= Im(the InternalRel of FT2,f.x)
    proof
      let y be object;
      assume y in f.:U_FT x;
      then consider x2 being object such that
A17:  x2 in dom f and
A18:  x2 in Im(Nbds2(n,1),x) and
A19:  y=f.x2 by FUNCT_1:def 6;
      consider u2,v2 being object such that
      u2 in Seg n and
      v2 in Seg 1 and
A20:  x2= [u2,v2] by A17,ZFMISC_1:def 2;
      x2=[f.x2,1] by A6,A17;
      then
A21:  u2=f.x2 by A20,XTUPLE_0:1;
A22:  Im(Nbds2(n,1),x) = [:{u}, Im(Nbdl1 1,v):] \/ [:Im(Nbdl1 n,u),{v}:]
      by A13,A14,A15,Def4;
A23:  now
        per cases by A18,A22,A20,XBOOLE_0:def 3;
        suppose
A24:      [u2,v2] in [:{u}, Im(Nbdl1 1,v):];
          reconsider pu=u as Element of FTSL1 n by A7,A13;
          (FTSL1 n) is filled by FINTOPO4:18;
          then
A25:      u in U_FT pu;
          u2 in {u} by A24,ZFMISC_1:87;
          hence u2 in Class(Nbdl1 n,u) by A7,A25,TARSKI:def 1;
        end;
        suppose
          [u2,v2] in [:Im(Nbdl1 n,u),{v}:];
          hence u2 in Class(Nbdl1 n,u) by ZFMISC_1:87;
        end;
      end;
      x=[f.x,1] by A6;
      hence thesis by A7,A15,A19,A21,A23,XTUPLE_0:1;
    end;
    Im(the InternalRel of FT2,f.x) c= f.:U_FT x
    proof
      set X=Im(Nbdl1 n,u), Y=Im(Nbdl1 1,v);
      reconsider nv=v as Nat by A14;
      let y be object;
      assume
A26:  y in Im(the InternalRel of FT2,f.x);
      Im(Nbdl1 n,f.x) c= rng f by A7,A8;
      then consider x3 being object such that
A27:  x3 in dom f and
A28:  y=f.x3 by A7,A26,FUNCT_1:def 3;
      set u2=f.x3,v2=1;
      x=[f.x,1] by A6;
      then
A29:  u2 in Im(Nbdl1 n,u) by A7,A15,A26,A28,XTUPLE_0:1;
A30:  Im(Nbds2(n,1),x) = [:{u}, Y:] \/ [:X,{v}:] by A13,A14,A15,Def4;
      1 <= nv & nv <= 1 by A14,FINSEQ_1:1;
      then
A31:  nv = 1 by XXREAL_0:1;
A32:  Im(Nbdl1 1,v) = {nv, max(nv-'1,1),min(nv+1,1)} by A14,FINTOPO4:def 3
        .= {1,max(0,1),min(2,1)} by A31,NAT_2:8
        .= {1,1,min(2,1)} by XXREAL_0:def 10
        .= {1, min(2,1)} by ENUMSET1:30
        .= {1, 1} by XXREAL_0:def 9
        .= {1} by ENUMSET1:29;
      then v2 in Im(Nbdl1 1,v) by ZFMISC_1:31;
      then [u2,v2] in [:Im(Nbdl1 n,u), Im(Nbdl1 1,v):] by A29,ZFMISC_1:def 2;
      then
A33:  [u2,v2] in [:X,{v}:] \/ [:{u},Y:] by A31,A32,XBOOLE_0:def 3;
      x3=[f.x3,1] by A6,A27;
      hence thesis by A27,A28,A33,A30,FUNCT_1:def 6;
    end;
    hence thesis by A16,XBOOLE_0:def 10;
  end;
  for x1,x2 being object st x1 in dom f & x2 in dom f & f.x1=f.x2
holds x1= x2
  proof
    let x1,x2 be object;
    assume that
A34: x1 in dom f and
A35: x2 in dom f & f.x1=f.x2;
    [f.x1,1]=x1 by A6,A34;
    hence thesis by A6,A35;
  end;
  then
A36: f is one-to-one by FUNCT_1:def 4;
  rng f= the carrier of FTSL1 n by A8,XBOOLE_0:def 10;
  then f is onto by FUNCT_2:def 3;
  then f is being_homeomorphism by A36,A12;
  hence thesis;
end;
