reserve FT for non empty RelStr,
  A,B,C for Subset of FT;

theorem Th15:
  for A being non empty Subset of FT holds A is connected iff FT|A is connected
proof
  let A be non empty Subset of FT;
A1: [#](FT|A)=A by Def3;
  thus A is connected implies (FT|A) is connected
  proof
    assume
A2: A is connected;
    for B2,C2 being Subset of (FT|A) st [#](FT|A) = B2 \/ C2 & B2 <> {} &
    C2 <> {} & B2 misses C2 holds B2^b meets C2
    proof
      let B2,C2 be Subset of (FT|A);
A3:   ([#](FT|A))/\ C2=C2 by XBOOLE_1:28;
      the carrier of (FT|A)=[#](FT|A) .=A by Def3;
      then reconsider B3=B2, C3=C2 as Subset of FT by XBOOLE_1:1;
      assume [#](FT|A) = B2 \/ C2 & B2 <> {} & C2 <> {} & B2 misses C2;
      then
A4:   B3^b meets C3 by A1,A2;
      B2^b /\ C2= B3^b /\ [#](FT|A)/\ C2 by Th12
        .= B3^b /\ C3 by A3,XBOOLE_1:16;
      then B2^b /\ C2 <> {} by A4;
      hence thesis;
    end;
    then [#](FT|A) is connected;
    hence thesis;
  end;
  assume (FT|A) is connected;
  then
A5: [#](FT|A) is connected;
  let B,C be Subset of FT;
  assume that
A6: A = B \/ C and
A7: B <> {} & C <> {} & B misses C;
A8: [#](FT|A) =A by Def3;
  then reconsider B2=B as Subset of (FT|A) by A6,XBOOLE_1:7;
  reconsider C2=C as Subset of (FT|A) by A6,A8,XBOOLE_1:7;
  ([#](FT|A))/\ C2=C2 & B2^b=B^b /\ [#](FT|A) by Th12,XBOOLE_1:28;
  then
A9: B^b /\ C = B2^b /\ C2 by XBOOLE_1:16;
  B2^b meets C2 by A5,A6,A7,A8;
  hence B^b /\ C <> {} by A9;
end;
