reserve E, x, y, X for set;
reserve A, B, C for Subset of E^omega;
reserve a, a1, a2, b for Element of E^omega;
reserve i, k, l, m, n for Nat;

theorem Th16:
  A |^.. (n + 1) = (A |^.. n) ^^ A
proof
  now
    let x be object;
    assume x in A |^.. (n + 1);
    then consider k such that
A1: n + 1 <= k and
A2: x in A |^ k by Th2;
    consider l such that
A3: l + 1 = k by A1,NAT_1:6;
    x in (A |^ l) ^^ (A |^ 1) by A2,A3,FLANG_1:33;
    then consider a, b such that
A4: a in A |^ l and
A5: b in A |^ 1 and
A6: x = a ^ b by FLANG_1:def 1;
    n <= l by A1,A3,XREAL_1:6;
    then a in A |^.. n by A4,Th2;
    then x in (A |^.. n) ^^ (A |^ 1) by A5,A6,FLANG_1:def 1;
    hence x in (A |^.. n) ^^ A by FLANG_1:25;
  end;
  then
A7: A |^.. (n + 1) c= (A |^.. n) ^^ A;
  now
    let x be object;
    assume x in (A |^.. n) ^^ A;
    then consider a, b such that
A8: a in (A |^.. n) and
A9: b in A and
A10: x = a ^ b by FLANG_1:def 1;
    consider k such that
A11: n <= k and
A12: a in A |^ k by A8,Th2;
A13: n + 1 <= k + 1 by A11,XREAL_1:6;
    b in A |^ 1 by A9,FLANG_1:25;
    then x in A |^ (k + 1) by A10,A12,FLANG_1:40;
    hence x in A |^.. (n + 1) by A13,Th2;
  end;
  then (A |^.. n) ^^ A c= A |^.. (n + 1);
  hence thesis by A7,XBOOLE_0:def 10;
end;
