
theorem Th16:
  for A,B,C,x being set holds C c= A implies ((id A)+*(B --> x))"(
  C \ {x}) = C \ B \ {x}
proof
  let A,B,C,x be set;
  assume
A1: C c= A;
  set f=((id A)+*(B --> x));
  thus f"(C \ {x}) c= C \ B \ {x}
  proof
    let x1 be object;
    assume
A2: x1 in f"(C \ {x});
    then
A3: f.x1 in (C \ {x}) by FUNCT_1:def 7;
A4: not x1 in B
    proof
      assume
A5:   x1 in B;
      then
A6:   x1 in dom(B --> x) by FUNCOP_1:13;
      then x1 in dom(id A) \/ dom(B --> x) by XBOOLE_0:def 3;
      then f.x1=(B --> x).x1 by A6,FUNCT_4:def 1;
      then
A7:   f.x1=x by A5,FUNCOP_1:7;
      not f.x1 in {x} by A3,XBOOLE_0:def 5;
      hence contradiction by A7,TARSKI:def 1;
    end;
    then
A8: not x1 in dom(B --> x);
    x1 in dom f by A2,FUNCT_1:def 7;
    then x1 in A \/ B by Th14;
    then
A9: x1 in A or x1 in B by XBOOLE_0:def 3;
    then x1 in dom(id A) by A4;
    then x1 in dom(id A) \/ dom(B --> x) by XBOOLE_0:def 3;
    then f.x1 = (id A).x1 by A8,FUNCT_4:def 1;
    then
A10: f.x1 = x1 by A4,A9,FUNCT_1:17;
    then
A11: not x1 in {x} by A3,XBOOLE_0:def 5;
    x1 in C \ B by A3,A4,A10,XBOOLE_0:def 5;
    hence thesis by A11,XBOOLE_0:def 5;
  end;
  let x1 be object;
  assume
A12: x1 in C \ B \ {x};
  then not x1 in {x} by XBOOLE_0:def 5;
  then
A13: x1 in C \ {x} by A12,XBOOLE_0:def 5;
A14: x1 in C by A12;
  then x1 in A by A1;
  then x1 in dom(id A);
  then
A15: x1 in dom(id A) \/ dom(B --> x) by XBOOLE_0:def 3;
  x1 in C \ B by A12,XBOOLE_0:def 5;
  then not x1 in dom(B --> x) by XBOOLE_0:def 5;
  then f.x1 = (id A).x1 by A15,FUNCT_4:def 1;
  then
A16: f.x1 = x1 by A1,A14,FUNCT_1:17;
  x1 in dom f by A15,FUNCT_4:def 1;
  hence thesis by A13,A16,FUNCT_1:def 7;
end;
