reserve p,p1,p2,q for Point of TOP-REAL 2,
  f,f1,f2,g,g1,g2 for FinSequence of TOP-REAL 2,
  r,s for Real,

  n,m,i,j,k for Nat,
  G for Go-board,
  x for set;
reserve f for non empty FinSequence of TOP-REAL 2;

theorem
  n in dom f & (for m st m in dom f holds (X_axis(f)).m <= (X_axis(f)).n
  ) implies f/.n in rng Line(GoB(f),len GoB(f))
proof
  set x = X_axis(f), y = Y_axis(f), r = x.n;
  assume that
A1: n in dom f and
A2: for m st m in dom f holds x.m <= r;
  reconsider p=f/.n as Point of TOP-REAL 2;
A3: dom f = Seg len f by FINSEQ_1:def 3;
A4: dom x = Seg len x & len x = len f by FINSEQ_1:def 3,GOBOARD1:def 1;
  then
A5: x.n=p`1 by A1,A3,GOBOARD1:def 1;
A6: rng Incr(x) = rng x by SEQ_4:def 21;
  x.n in rng x by A1,A3,A4,FUNCT_1:def 3;
  then consider i being Nat such that
A7: i in dom Incr(x) and
A8: Incr(x).i=p`1 by A5,A6,FINSEQ_2:10;
  reconsider i as Element of NAT by ORDINAL1:def 12;
A9: i<=len Incr(x) by A7,FINSEQ_3:25;
A10: 1<=i by A7,FINSEQ_3:25;
A11: now
    reconsider s=Incr(x).(i+1) as Real;
    assume i <> len Incr(x);
    then i<len Incr(x) by A9,XXREAL_0:1;
    then
A12: i+1<=len Incr(x) by NAT_1:13;
    1<=i+1 by A10,NAT_1:13;
    then
A13: i+1 in dom Incr(x) by A12,FINSEQ_3:25;
    then Incr(x).(i+1) in rng Incr(x) by FUNCT_1:def 3;
    then
A14: ex m being Nat st m in dom x & x.m=s by A6,FINSEQ_2:10;
    i<i+1 by NAT_1:13;
    then r<s by A5,A7,A8,A13,SEQM_3:def 1;
    hence contradiction by A2,A3,A4,A14;
  end;
A15: rng Incr(y) = rng y by SEQ_4:def 21;
  dom y = Seg len y & len y = len f by FINSEQ_1:def 3,GOBOARD1:def 2;
  then y.n=p`2 & y.n in rng y by A1,A3,FUNCT_1:def 3,GOBOARD1:def 2;
  then consider j being Nat such that
A16: j in dom Incr(y) and
A17: Incr(y).j=p`2 by A15,FINSEQ_2:10;
A18: p=|[p`1,p`2]| by EUCLID:53;
  len Line(GoB(f),len GoB(f))=width GoB(f) by MATRIX_0:def 7;
  then
A19: dom Line(GoB(f),len GoB(f))= Seg width GoB(f) by FINSEQ_1:def 3;
  width GoB(f) = card rng y & len Incr(y) = card rng y by Th13,SEQ_4:def 21;
  then
A20: dom Incr(y) = Seg width GoB(f) by FINSEQ_1:def 3;
A21: len GoB(f)=card rng x & len Incr(x) = card rng x by Th13,SEQ_4:def 21;
  then Indices GoB(f) = [:dom GoB(f), Seg width GoB(f):] & dom Incr(x) = dom
  GoB(f) by FINSEQ_3:29,MATRIX_0:def 4;
  then [len GoB(f),j] in Indices GoB(f) by A21,A7,A16,A20,A11,ZFMISC_1:87;
  then GoB(f)*(len GoB(f),j) = |[p`1,p`2]| by A21,A8,A17,A11,Def1;
  then (Line(GoB(f),len GoB(f))).j = f/.n by A16,A20,A18,MATRIX_0:def 7;
  hence thesis by A16,A20,A19,FUNCT_1:def 3;
end;
