reserve i,j,k for Nat,
  r,s,r1,r2,s1,s2,sb,tb for Real,
  x for set,
  GX for non empty TopSpace;
reserve GZ for non empty TopSpace;
reserve f for non constant standard special_circular_sequence,
  G for non empty-yielding Matrix of TOP-REAL 2;

theorem Th16:
  for G being Matrix of TOP-REAL 2 holds h_strip(G,j) is closed
proof
  let G be Matrix of TOP-REAL 2;
  now
    per cases;
    case
A1:   j<1;
A2:   now
        assume j >= width G;
        then h_strip(G,j)={ |[r,s]| : G*(1,j)`2 <= s } by GOBOARD5:def 2;
        hence thesis by Th13;
      end;
      now
        assume j<width G;
        then h_strip(G,j) = { |[r,s]| : s <= G*(1,j+1)`2 } by A1,GOBOARD5:def 2
;
        hence thesis by Th12;
      end;
      hence thesis by A2;
    end;
    case
      1 <= j & j < width G;
      then
A3:   h_strip(G,j) = { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 } by
GOBOARD5:def 2;
      reconsider P2={ |[r1,s1]| : s1<= G*(1,j+1)`2 } as Subset of TOP-REAL 2
      by Lm5;
      reconsider P1={ |[r1,s1]| : G*(1,j)`2 <= s1} as Subset of TOP-REAL 2 by
Lm3;
A4:   { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 }= { |[r1,s1]| : G*(1
      ,j)`2 <= s1} /\ {|[r2,s2]| : s2 <= G*(1,j+1)`2 }
      proof
A5:     { |[r1,s1]| : G*(1,j)`2 <= s1} /\ {|[r2,s2]| : s2 <= G*(1,j+1)`2
        } c= { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 }
        proof
          let x be object;
          assume
A6:       x in { |[r1,s1]| : G*(1,j)`2 <= s1} /\ {|[r2,s2]| : s2 <= G
          * (1,j+1)`2 };
          then
A7:       x in { |[r1,s1]| : G*(1,j)`2 <= s1} by XBOOLE_0:def 4;
          x in {|[r2,s2]| : s2 <= G*(1,j+1)`2 } by A6,XBOOLE_0:def 4;
          then consider r2,s2 such that
A8:       |[r2,s2]|=x and
A9:       s2 <= G*(1,j+1)`2;
          consider r1,s1 such that
A10:      |[r1,s1]|=x and
A11:      G*(1,j)`2 <= s1 by A7;
          s1=s2 by A10,A8,SPPOL_2:1;
          hence thesis by A10,A11,A9;
        end;
A12:    { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 } c= {|[r1,s1]| : G
        *(1,j)`2 <= s1 }
        proof
          let x be object;
          assume x in { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 };
          then ex r,s st x=|[r,s]| & G*(1,j)`2 <= s & s <= G*(1,j+1)`2;
          hence thesis;
        end;
        { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 } c= {|[r1,s1]| :
        s1 <= G*(1,j+1)`2 }
        proof
          let x be object;
          assume x in { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 };
          then ex r,s st x=|[r,s]| & G*(1,j)`2 <= s & s <= G*(1,j+1)`2;
          hence thesis;
        end;
        then { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 } c= { |[r1,s1]| :
G*(1,j)`2 <= s1} /\ {|[r2,s2]| : s2 <= G*(1,j+1)`2 } by A12,XBOOLE_1:19;
        hence thesis by A5;
      end;
      P1 is closed & P2 is closed by Th12,Th13;
      hence thesis by A3,A4,TOPS_1:8;
    end;
    case
      j >= width G;
      then h_strip(G,j) = { |[r,s]| : G*(1,j)`2 <= s } by GOBOARD5:def 2;
      hence thesis by Th13;
    end;
  end;
  hence thesis;
end;
