reserve F,G for Group;
reserve G1 for Subgroup of G;
reserve Gc for cyclic Group;
reserve H for Subgroup of Gc;
reserve f for Homomorphism of G,Gc;
reserve a,b for Element of G;
reserve g for Element of Gc;
reserve a1 for Element of G1;
reserve k,m,n,p,s for Element of NAT;
reserve i0,i,i1,i2 for Integer;
reserve j,j1 for Element of INT.Group;
reserve x,y,t for set;

theorem
  for Gc being strict cyclic Group st Gc is infinite holds INT.Group,Gc
  are_isomorphic
proof
  let Gc be strict cyclic Group;
  consider g being Element of Gc such that
A1: for h be Element of Gc holds ex i st h=g|^i by GR_CY_1:17;
  assume
A2: Gc is infinite;
  ex h being Homomorphism of INT.Group,Gc st h is bijective
  proof
    deffunc F(Element of INT.Group) = g|^@'$1;
    consider h being Function of the carrier of INT.Group,the carrier of Gc
    such that
A3: for j1 be Element of INT.Group holds h.j1=F(j1) from FUNCT_2:sch 4;
A4: Gc=gr {g} by A1,Th5;
A5: h is one-to-one
    proof
      let x,y be object;
      assume that
A6:   x in dom h and
A7:   y in dom h and
A8:   h.x=h.y and
A9:   x<>y;
      reconsider y9=y as Element of INT.Group by A7,FUNCT_2:def 1;
      reconsider x9=x as Element of INT.Group by A6,FUNCT_2:def 1;
      g|^@'x9=h.y9 by A3,A8
        .= g|^@'y9 by A3;
      hence contradiction by A2,A4,A9,Th14;
    end;
A10: dom h = the carrier of INT.Group by FUNCT_2:def 1;
A11: the carrier of Gc c= rng h
    proof
      let x be object;
      assume x in the carrier of Gc;
      then reconsider z=x as Element of Gc;
      consider i such that
A12:  z=g|^i by A1;
      reconsider i9=i as Element of INT.Group by INT_1:def 2;
      i=@'i9;
      then x = h.(i9) by A3,A12;
      hence thesis by A10,FUNCT_1:def 3;
    end;
    rng h c= the carrier of Gc by RELAT_1:def 19;
    then
A13: rng h = the carrier of Gc by A11,XBOOLE_0:def 10;
    for j,j1 holds h.(j*j1)=h.(j)*h.(j1)
    proof
      let j,j1;
      @'(j*j1)= @'j+@'j1;
      then h.(j*j1) = g|^(@'j+@'j1) by A3
        .= (g|^@'j)*(g|^@'j1) by GROUP_1:33
        .= h.(j)*(g|^@'j1) by A3
        .= h.(j)*h.(j1) by A3;
      hence thesis;
    end;
    then reconsider h as Homomorphism of INT.Group,Gc by GROUP_6:def 6;
    take h;
    h is onto by A13,FUNCT_2:def 3;
    hence thesis by A5,FUNCT_2:def 4;
  end;
  hence thesis by GROUP_6:def 11;
end;
