reserve i,j,n,n1,n2,m,k,l,u for Nat,
        r,r1,r2 for Real,
        x,y for Integer,
        a,b for non trivial Nat,
        F for XFinSequence,
        cF,cF1,cF2 for complex-valued XFinSequence,
        c,c1,c2 for Complex;

theorem Th16:
  for x,y,z being Nat holds
       x >= z & y = x choose z
  iff
     ex u,v,y1,y2,y3 being Nat st
       y1 = x|^z & y2 = (u+1)|^x & y3 = u|^z &
       u > y1 & v = [\y2/y3/] & y,v are_congruent_mod u & y < u & x >=z
proof
  let x,y,z be Nat;
  thus x>=z & y = x choose z implies
     ex u,v,y1,y2,y3 be Nat st
       y1 = x|^z & y2 = (u+1)|^x & y3 = u|^z &
       u > y1 & v = [\y2/y3/] & y,v are_congruent_mod u & y < u & x >=z
  proof
    assume
A1:   x>=z & y = x choose z;
    set y1 =x|^z, u = y1+1,y2 = (u+1)|^x,y3=u|^z,v=[\y2/y3/];
    reconsider v as Element of NAT by INT_1:3,INT_1:54;
    take u,v,y1,y2,y3;
    thus
A2:   y1 = x|^z & y2 = (u+1)|^x & y3 = u|^z &
    u > y1 & v = [\y2/y3/] by NAT_1:13;
A3:   v mod u = y by A2,Th15,A1;
    y < u by A1,NAT_1:13,Th13;
    then y mod u = y by NAT_D:24;
    then y-v mod u = 0 by A3,INT_4:22;
    then u divides y-v by INT_1:62;
    hence thesis by A1,NAT_1:13,Th13,INT_1:def 4;
  end;
  given u,v,y1,y2,y3 be Nat such that
A4: y1 = x|^z & y2 = (u+1)|^x & y3 = u|^z and
A5: u > y1 & v = [\y2/y3/] & y,v are_congruent_mod u and
A6: y < u & x >=z;
  u divides y-v by A5,INT_1:def 4;
  then y-v mod u =0 by INT_1:62,A5;
  then y mod u = v mod u by INT_4:22,A5;
  then y mod u = x choose z by Th15,A4,A5,A6;
  hence thesis by A6,NAT_D:24;
end;
