reserve A for non trivial Nat,
        B,C,n,m,k for Nat,
        e for Nat;
reserve a for non trivial Nat;

theorem Th16:
  for f,k be Nat st f = k! & k > 0 holds
    ex m,r,s,t,u be Nat,W,U,S,T,Q be Nat, M be non trivial Nat st
      m>0 & u>0 &
      r + W + 1 = Py(M*(U+1),W+1) &
      (M^2-1)*S^2 +1 is square &
      ((M*U)^2 -1)*T^2 + 1 is square &
      W^2*u^2 - (W^2-1)*S*u-1,0 are_congruent_mod Q &
      (4*f^2 -1)*(r-m*S*T*U)^2 + 4*u^2*S^2*T^2 < 8*f*u*S*T*(r-m*S*T*U) &
      W = 100*f*k*(k+1) &
      U = 100 * (u|^3)*(W|^3)+1 &
      M = 100 * m * U *W+1 &
      S = (M-1)*s+k+1 &
      T = (M*U-1)*t +W-k+1 &
      Q = 2*M*W-W^2 -1
proof
  let f,k be Nat such that
A1: f = k! & k > 0;
  set W = 100*f*k*(k+1),u = W|^k,U = 100 * (u|^3)*(W|^3)+1;
  set IW = (U,1) In_Power W, IWk=IW|k;
A2: len IW = W+1 by NEWTON:def 4;
  (f*k*100)*(k+1) >= (f*k*100)*1 & f >=1 by XREAL_1:64,A1,NAT_1:14;
  then W >= f*(100*k) >= 1*(100*k) by XREAL_1:64;
  then
A3: W>= 100*k>=5*k & 100*k>=1*k & 100*k>=3*k by XXREAL_0:2,XREAL_1:64;
  then
A4: W>= 5*k & W>= k & W>= 3*k by XXREAL_0:2;
A5: k <= W by A3,XXREAL_0:2;
  k>=1 by A1,NAT_1:14;
  then 1+0 < k+k by XREAL_1:8;
  then
A6: 1+0 +k < k+k+k by XREAL_1:6;
  then
A7: k +1 < W by A4,XXREAL_0:2;
  W|^(1+1) = W* W|^1 & W|^1=W by NEWTON:6;
  then
A8: W|^(2+1) = W*W*W by NEWTON:6;
  u|^(1+1) = u* u|^1 & u|^1=u by NEWTON:6;
  then
A9: u|^(2+1) = u*u*u by NEWTON:6;
  u|^(2+1) >= u*1 & W|^3 >=1 & u|^3 >= 1 & W|^3 >=W*1
  by A1,NAT_1:14,A8,A9,XREAL_1:64;
  then u|^3 * W|^3 >= 1*u & u|^3 * W|^3 >= 1*W by XREAL_1:66;
  then
A10: u|^3 * W|^3 *100 >= (1*u)*12 & u|^3 * W|^3 *100 >= (1*W)*2 by XREAL_1:66;
  A11: 2*W <= U by A10,NAT_1:13;
  reconsider Wk=W-k as Nat by A3,XXREAL_0:2,NAT_1:21;
  A12:  k < W+1 by A5,NAT_1:13;
  then A13:len IWk = k by A2,FINSEQ_1:59;
  consider IWW be FinSequence such that
A14: IW = IWk^IWW by FINSEQ_1:80;
  reconsider IWW as FinSequence of REAL by A14,FINSEQ_1:36;
  reconsider k1=k-1 as Nat by A1;
A15: len (IWk^IWW) = k+ len IWW by A13,FINSEQ_1:22;
  then
A16: len IWW = Wk+1 by A2,A14;
A17: len IWk = k1-0+1 by A12,A2,FINSEQ_1:59;
A18: for i be Nat st i+1 in dom IWk holds IWk.(i+1) =
    (W choose (0+i)) * (U |^(W-'(0+i)))
  proof
    let i be Nat such that
A19: i+1 in dom IWk;
A20: i+1 in dom IW by A19,RELAT_1:57;
    i+1 <= k by A19,FINSEQ_3:25,A13;
    then i+1 <= W by A5,XXREAL_0:2;
    then i < W by NAT_1:13;
    then
A21: W-'i = W -i by XREAL_1:233;
A22: i+1-1=i;
    IWk.(i+1) = IW.(i+1) by A19,FUNCT_1:47
    .= (W choose i) * U|^(W-'i) * 1|^i by A20,A22,A21,NEWTON:def 4;
    hence thesis;
  end;
A23: W|^0=1 & W-'0=W-0 by XREAL_1:233,NEWTON:4;
  k1 <k1+1 by NAT_1:13;
  then k1 < W by A5,XXREAL_0:2;
  then
A24: 0 < Sum IWk  < 2*(W|^0) * (U|^(W-'0)) by Th14,A11,A17,A18;
  set UIWk = (1/ (U|^(Wk+1)))* IWk;
A25: 1 / U * U = 1 by XCMPLX_1:87;
  U|^(Wk+1) = (U|^Wk)* U by NEWTON:6;
  then 1/ (U|^(Wk+1)) = (1/ U) * (1/(U|^Wk)) by XCMPLX_1:102;
  then
A26: (1/ (U|^(Wk+1)))* (U |^Wk) = (1/ U) * ((1/(U|^Wk)) * (U |^Wk))
  .= (1/ U)*1 by XCMPLX_1:87;
  rng UIWk c= NAT
  proof
    let y be object such that
A27: y in rng UIWk;
    consider i be object such that
A28: i in dom UIWk & UIWk.i = y by A27,FUNCT_1:def 3;
    reconsider i as Nat by A28;
A29: dom UIWk = dom IWk by VALUED_1:def 5;
    then
A30: 1<= i <= k by A28, FINSEQ_3:25,A13;
    then reconsider i1 = i-1 as Nat;
    i=i1+1;
    then i1 <k by A30,NAT_1:13;
    then
A31:  k-'i1 = k-i1 & W-'i1 = W-i1 & k-'i = k-i
      by A5,XXREAL_0:2,A30,XREAL_1:233;
    then
A32:  W-'i1 = Wk + (k-'i1);
    k-'i1 = (k-'i)+1 by A31;
    then
A33: (U|^ (k-'i1)) * (1/U) = ((U|^ (k-'i))*U) * (1/U) by NEWTON:6
    .=(U|^ (k-'i))*(U * (1/U))
    .= U|^ (k-'i) by A25;
    IWk.(i1+1) = (W choose (0+i1)) * (U |^(W-'(0+i1))) by A29,A28,A18;
    then UIWk.i = (1/(U|^(Wk+1)))*((W choose i1)*(U|^(W-'i1))) by VALUED_1:6
    .= (1/ (U|^(Wk+1)))* ((W choose i1) * ((U|^Wk) * (U|^ (k-'i1))))
    by A32,NEWTON:8
    .= (W choose i1)*(U|^ (k-'i)) by A33,A26;
    hence thesis by A28;
  end;
  then reconsider UIWk as FinSequence of NAT by FINSEQ_1:def 4;
  reconsider Z=Sum UIWk as Element of NAT by ORDINAL1:def 12;
A34: U |^(Wk+k)= (U |^Wk) * (U |^k) by NEWTON:8;
A35: Z = (1/ (U|^(Wk+1)))* Sum IWk < (1/ (U|^(Wk+1)))* (2* (U |^Wk) * (U |^k))
    by A34, XREAL_1:68,A24,A23,RVSUM_1:87;
  set m=Z,M = 100 * m * U *W+1;
  set mu = M*(U+1);
  reconsider M as non trivial Nat by A35,A24,A1;
  reconsider MU=M*U as non trivial Nat;
  set S = Py(M,k+1);
  set T = Py(MU,Wk+1);
  reconsider r = Py(mu,W+1) - (W+1) as Nat by NAT_1:21,HILB10_1:13;
  consider s be Integer such that
A36:  (M-1)*s = S -(k+1) by INT_1:def 5,HILB10_1:24;
  S -(k+1) >=k+1 -(k+1) by XREAL_1:9,HILB10_1:13;
  then s >=0 by A36;
  then reconsider s as Element of NAT by INT_1:3;
  consider t be Integer such that
A37:  (MU-1)*t = T -(Wk+1) by INT_1:def 5,HILB10_1:24;
  T -(Wk+1) >=Wk+1 -(Wk+1) by XREAL_1:9,HILB10_1:13;
  then t >=0 by A37;
  then reconsider t as Element of NAT by INT_1:3;
A38:  (MU-1)*t + Wk+1 = T by A37;
  set   Q = 2*M*W-W^2 -1;
A39: M*W -1 >= 0 by A1;
  100 * m * U * W >= 1*W by XREAL_1:64,A35,A24,NAT_1:14;
  then M> 1*W by NAT_1:13;
  then M*W >= W*W = W^2 by XREAL_1:64,SQUARE_1:def 1;
  then M*W+M*W >= M*W+W^2 by XREAL_1:7;
  then M*W+M*W -(W^2+1) >= M*W+W^2 -(W^2+1) by XREAL_1:9;
  then reconsider Q as Element of NAT by A39,INT_1:3;
  M^2=M*M by SQUARE_1:def 1;
  then
A40: M^2-'1 = M^2-1 by NAT_1:14,XREAL_1:233;
A41: Px(M,k+1)^2 - (M^2-1) *S^2 = 1 by A40,HILB10_1:7;
  MU^2=MU*MU by SQUARE_1:def 1;
  then
A42: MU^2-'1 = MU^2-1 by XREAL_1:233,NAT_1:14;
  Px(MU,Wk+1)^2 - (MU^2-1) *T^2 = 1 by A42,HILB10_1:7;
  then
A43:  (MU^2 -1)*T^2 + 1 is square;
A44: for i be Nat st i+1 in dom IWW holds IWW.(i+1) =
    (W choose (k+i)) * (U |^(W-'(k+i)))
  proof
    let i be Nat such that
A45: i+1 in dom IWW;
A46: k+(i+1) in dom IW by A45,A13,A14,FINSEQ_1:28;
    then k+i+1 <= W+1 by A2,FINSEQ_3:25;
    then
A47: W-'(k+i) = W-(k+i) by XREAL_1:6,233;
A48: k+(i+1)-1 = k+i;
    IWW.(i+1) = IW.(k+(i+1)) by FINSEQ_1:def 7,A13,A14,A45
    .= (W choose (k+i)) * U|^(W-'(k+i)) * 1|^(k+i) by A46,A48,A47,NEWTON:def 4;
    hence thesis;
  end;
A49: 0 < Sum IWW  < 2*(W|^k) * (U|^(W-'k)) by A16,Th14,A11,A5,A1,A44;
  set UIWW = (1/ (U|^(Wk+1)))* IWW;
  set D = Sum UIWW;
A50: W-'k = Wk by A3,XXREAL_0:2,XREAL_1:233;
A51: U>=1 by NAT_1:14;
  100 * m * U *W>= 1*W by A35,A24,NAT_1:14,XREAL_1:64;
  then W+1 <= M-1+1 by XREAL_1:6;
  then
A52: (W+1)*1 <= M*U by A51,XREAL_1:66;
  U < U+1 by NAT_1:13;
  then M*U <=M*(U+1) by XREAL_1:64;
  then W+1 <= M*(U+1) by A52,XXREAL_0:2;
  then W < M*(U+1) by NAT_1:13;
  then consider t1 be _Theta such that
A53: Py(mu,W+1) = (2*mu) |^W *(1+t1*(W/mu)) by Th10;
  reconsider I=1 as _Theta by Def1;
  set E=t1*(W/mu)- ( W+1) / (2*mu) |^W;
  W|^(1+1) = W* W|^1 & W|^1=W by NEWTON:6;
  then
A54: W|^(2+1) = W*W*W by NEWTON:6;
A55: W>=1 by A1,NAT_1:14;
A56:2*mu >=1 by NAT_1:14;
  (f*k*100)*(k+1) >= (f*k*100)*1 & f >=1 by XREAL_1:64,A1,NAT_1:14;
  then W >= f*(100*k) >= 1*(100*k) by XREAL_1:64;
  then W>= 100*k>=5*k & 100*k>=1*k by XXREAL_0:2,XREAL_1:64;
  then
A57: k <= W by XXREAL_0:2;
  u>=1 by NAT_1:14,A1;
  then
A58: u|^3 >= u & W|^3 >=1 & W|^3 >= W & u|^3 >=1 by A55,PREPOWER:12,NAT_1:14;
  then u|^3*W|^3 >= u*1 & u|^3*W|^3 >= W*1 by XREAL_1:66;
  then U > 100*(u|^3*W|^3) >= 100*u & 100*(u|^3*W|^3) >=100*W
  by XREAL_1:64,NAT_1:13;
  then
A59: U >= 100 *u >= 12* u & U >= 100*W  & 100*u >= 16* u
    by XXREAL_0:2,XREAL_1:64;
  m*U >=1 by NAT_1:14,A35,A24;
  then (100*W)*(m*U) >= 100*W*1 >= 5 * k by A57,XREAL_1:66;
  then (100*W)*(m*U) >= 5*k by XXREAL_0:2;
  then
A60: 5*k <= M by NAT_1:13;
  then
A61: (5*k)/M <=1 by XREAL_1:183;
A62: 2*k <= 5*k by XREAL_1:64;
  then
A63: M>=2*k by A60,XXREAL_0:2;
  then (2*k)/M <=1 by XREAL_1:183;
  then
A64:  2*(k/M)<=1 by XCMPLX_1:74;
A65: 4*W <= 100*W & 2*W <= 100*W by XREAL_1:64;
  then
A66: 4*W <= U & 2*W <= U by A59,XXREAL_0:2;
  then
A67: (2*W) <= U+1 by NAT_1:13;
  W <= W+W by NAT_1:11;
  then
A68: W <=U by A66,XXREAL_0:2;
  Wk <= W-0 by XREAL_1:10;
  then 4* Wk <= 4*W & 2* Wk <= 2*W by XREAL_1:64;
  then
A69: 4*Wk <= U & 2*Wk <= U by A66,XXREAL_0:2;
  then (4*Wk)/U <=1 by XREAL_1:183;
  then
A70: (4*Wk)/U* (1/M) <= 1 * (1/M) by XREAL_1:64;
  2*(2*(Wk/MU)) = 4 *(Wk/MU)
  .= (4*Wk)/MU by XCMPLX_1:74
  .= (4*Wk)/U* (1/M) by XCMPLX_1:103;
  then
A71: 2*(1/M) + 2*(2*(Wk/MU)) <= 2*(1/M) + 1 * (1/M) = 3*(1/M) =(3*1)/M
    by A70,XREAL_1:6,XCMPLX_1:74;
  3*1 <= 3*k by XREAL_1:64,A1,NAT_1:14;
  then (3*1)/M <= (3*k) /M by XREAL_1:72;
  then 2*(1/M) + 2*(2*(Wk/MU)) <= (3*k) /M by A71,XXREAL_0:2;
  then
A72: 2*(k/M)+ (2*(1/M) + 2*(2*(Wk/MU))) <= 2*(k/M)+ (3*k) /M
    by XREAL_1:6;
  2*(k/M) = (2*k)/M by XCMPLX_1:74;
  then
A73: 2*(k/M)+ (3*k) /M = (2*k+3*k)/M by XCMPLX_1:62;
  then 2*(k/M)+ 2*(1/M) + 0 <= 2*(k/M)+ 2*(1/M) + 2*(2*(Wk/MU)) <= 1
    by A72,A61,XXREAL_0:2,XREAL_1:6;
  then
A74: 2*(k/M)+ 2*(1/M) <= 1 by XXREAL_0:2;
A75: 2*W <= U by A65,A59,XXREAL_0:2;
  M>=1 by NAT_1:14;
  then
A76: MU>=1*(2*Wk) by A69,XREAL_1:66;
  2*k >= 1*k by XREAL_1:64;
  then consider t3 be _Theta such that
A77: Py(M,k+1) = (2*M)|^k *(1+ t3*(k/M)) by Th10,A63,XXREAL_0:2;
  2*Wk >= 1*Wk by XREAL_1:64;
  then consider t4 be _Theta such that
A78: Py(MU,Wk+1) = (2*MU)|^Wk *(1+ t4*(Wk/MU)) by Th10,A76,XXREAL_0:2;
  1*M>=2*k by A62,A60,XXREAL_0:2;
  then k/M <=1/2 by XREAL_1:102;
  then consider T3 be _Theta such that
A79: 1/ (1+ t3*(k/M)) = 1+T3*2*(k/M) by Th7;
  1*MU>=2*Wk by A76;
  then Wk/MU <=1/2 by XREAL_1:102;
  then consider T4 be _Theta such that
A80: 1/ (1+ t4*(Wk/MU)) = 1+T4*2*(Wk/MU) by Th7;
  1* mu >= M * (2*W) by A67,XREAL_1:64;
  then (W*(2*M))/mu <= 1 by XREAL_1:79;
  then (2*M)*(W/mu) <= 1 by XCMPLX_1:74;
  then
A81: W/mu <= 1/(2*M) by XREAL_1:77;
  then
A82: -(W/mu) >= - 1/(2*M) by XREAL_1:24;
  -1 <= t1 <= 1 by Def1;
  then (-1)*(W/mu) <= t1*(W/mu) <= 1*(W/mu) by XREAL_1:64;
  then
A83: -(1/(2*M)) <= t1*(W/mu) <= 1/(2*M) by A81,A82,XXREAL_0:2;
  W+1 <= U+1 by A68,XREAL_1:6;
  then
A84: (W+1)*(2*M) <= (U+1) * (2*M) by XREAL_1:64;
  (2*mu) <= (2*mu) |^W by A56,A55,PREPOWER:12;
  then (W+1) *(2*M) <= 1 * (2*mu) |^W by A84,XXREAL_0:2;
  then ( W+1) / (2*mu) |^W <= 1/(2*M) by XREAL_1:102;
  then 1/(2*M) >= - ( W+1) / (2*mu) |^W >= - 1/(2*M) by XREAL_1:24;
  then
A85: - 1/(2*M) + -1/(2*M) <= t1*(W/mu) + - ( W+1) / (2*mu) |^W
    <= 1/(2*M)+1/(2*M) by A83,XREAL_1:7;
A86: (1*1)/(2*M) = 1/2 * (1/M) by XCMPLX_1:76;
A87:t1*(W/mu)- ( W+1) / (2*mu) |^W <= I* (1/M) by A85,A86;
A88: (-I) * (1/M) <= t1*(W/mu)- ( W+1) / (2*mu)|^W by A85,A86;
  consider t2 be _Theta such that
A89:  t1*(W/mu)- ( W+1) / (2*mu)|^W = t2 * (1/M) by A87,A88,Th4;
  consider T5 be _Theta such that
A90: (1+T3*(2*(k/M)))* (1 + t2 * (1/M)) =1+T5*(2*(k/M)+ 2*(1/M))by A64,Th3;
  consider T6 be _Theta such that
A91: (1+T5*(2*(k/M)+ 2*(1/M)))* (1+T4*(2*(Wk/MU))) =
    1+T6 *(2*(k/M)+ 2*(1/M) + 2*(2*(Wk/MU))) by A74,Th3;
    A92: |.2*(k/M)+ 2*(1/M) + 2*(2*(Wk/MU)).| = 2*(k/M)+ 2*(1/M)
    + 2*(2*(Wk/MU));
A93:|.(5*k)/M.| = (5*k)/M;
  consider T7 be _Theta such that
A94: T6*(2*(k/M)+ 2*(1/M) + 2*(2*(Wk/MU))) = T7* ((5*k)/M)
  by A73,A72,A92,A93,Th2;
A95: 1/S = (1/(2*M)|^k) * (1+T3*2*(k/M)) by A79,A77,XCMPLX_1:102;
A96: 1/T = (1/(2*MU)|^Wk) *(1+T4*2*(Wk/MU)) by A80,A78,XCMPLX_1:102;
A97:(2*mu) |^W = ((2*M)*(U+1)) |^W
  .= ((2*M)|^W) *((U+1) |^W) by NEWTON:7;
  ((2*M)*U)|^Wk = (2*M) |^Wk * U|^Wk by NEWTON:7;
  then
A98:((2*M)|^k) * ((2*MU)|^Wk) = (2*M)|^k * (2*M) |^Wk * U|^Wk
  .= (2*M)|^(k+Wk) * U|^Wk by NEWTON:8;
  (1/(2*M)|^k) * (1/(2*MU)|^Wk)
  = 1/ ( (2*M)|^W * U|^Wk) by A98,XCMPLX_1:102;
  then
A99: ((2*mu) |^W) * (1/(2*M)|^k) * (1/(2*MU)|^Wk) =
  (((2*M)|^W) *((U+1) |^W)) *(1 / ( (2*M)|^W * U|^Wk)) by A97
  .= (((2*M)|^W) *((U+1) |^W)) / ( (2*M)|^W * U|^Wk) by XCMPLX_1:99
  .= ((U+1) |^W) / (U|^Wk) by XCMPLX_1:91;
  r = (2*mu) |^W *(1+t1*(W/mu)) - ( ((W+1) / (2*mu)|^W) * ((2*mu)|^W))
  by A53,XCMPLX_1:87;
  then r = (2*mu) |^W *((1+t1*(W/mu)) - (W+1) / (2*mu)|^W  );
  then
A100: r = (2*mu) |^W * (1 + t2 * (1/M)) by A89;
A101: r/(S*T) = r * (1/(S*T)) by XCMPLX_1:99
  .= r * ((1/S) *(1/T)) by XCMPLX_1:102
  .= (((U+1) |^W) / (U|^Wk)) *
  ( (1 + t2 * (1/M)) * (1+T3*2*(k/M)) * (1+T4*2*(Wk/MU))) by A96,A95,A99,A100
  .= (((U+1) |^W) / (U|^Wk)) *(1+T7* ((5*k)/M)) by A90,A91,A94;
A102: D = (1/ (U|^(Wk+1)))* Sum IWW < (1/ (U|^(Wk+1)))* (2*(W|^k) * (U|^Wk))
    by A50, XREAL_1:68,A49,RVSUM_1:87;
  (U+1) |^W = Sum IW = Sum IWk + Sum IWW by A14,RVSUM_1:75,NEWTON:30;
  then
A103: Z+D = (1/ (U|^(Wk+1))) * ((U+1) |^W) by A102,A35
  .= ((U+1) |^W) / (U|^(Wk+1)) by XCMPLX_1:99;
A104: W >= k+1 by A6,A4,XXREAL_0:2;
A105: W > k by NAT_1:13,A7;
A106: k >=1 by A1,NAT_1:14;
A107: k-'0 = k-0 & W-'0 = W-0 & k-'1 = k-1 by A1,NAT_1:14,XREAL_1:233;
  then W-'0 = Wk + (k-'0);
  then
A108: U|^(W-'0) = (U|^Wk) * (U|^ (k-'0)) by NEWTON:8;
  k-'0 = (k-'1)+1 by A107;
  then
A109: (U|^ (k-'0)) * (1/U) = ((U|^ (k-'1))*U) * (1/U) by NEWTON:6
  .=(U|^ (k-'1))*(U * (1/U))
  .= U|^ (k-'1) by A25;
  IWk.(0+1)= (W choose (0+0)) * (U |^(W-'(0+0))) by A13,FINSEQ_3:25,A106,A18;
  then
A110: UIWk.1 = (1/ (U|^(Wk+1)))* ((W choose 0) * (U |^(W-'0))) by VALUED_1:6
  .= (W choose 0)*(U|^ k1) by A107,A109,A26,A108
  .= 1*(U|^ k1) by NEWTON:19;
  reconsider Z=Sum UIWk as Element of NAT by ORDINAL1:def 12;
  consider uiwk be FinSequence of NAT,y be Element of NAT such that
A111:    UIWk = <*y*>^uiwk by A17,FINSEQ_2:130;
  Sum UIWk = y+ Sum uiwk by A111,RVSUM_1:76;
  then
A112: Sum UIWk>=y+0 by XREAL_1:6;
A113: U*U|^ k1 = U|^(k1+1) by NEWTON:6;
  100*U*W*m >= 100*U*W * U|^ k1 by A112,A110,A111,XREAL_1:64;
  then
A114: M > 100*W * U|^k by A113,NAT_1:13;
  (k+1) * (f * k) >= 1* (f * k) by NAT_1:11,XREAL_1:64;
  then (k+1) * (f * k)*100 >= 1* (f * k)*3 by XREAL_1:66;
  then 100 * U|^k *W >= 100 * U|^k *(3 * f * k) by XREAL_1:64;
  then
A115: M > 300 * (U|^k *( f * k)) by A114,XXREAL_0:2;
A116: 300 * (U|^k *( f * k)) >= 240 * (U|^k *( f * k)) by XREAL_1:64;
  then
A117: 240 * f * k * U|^k < M by XXREAL_0:2,A115;
  (f*k)*k <= (f*k)*(k+1) by NAT_1:11,XREAL_1:64;
  then (f*k)*k*96 <= (f*k)*(k+1)*100 by XREAL_1:66;
  then
A118: 96*f*(k*k) <= W & k^2=k*k by SQUARE_1:def 1;
  then 12* (8*f*k^2) <= 1*W;
  then
A119: (8*f*k^2)/W <=1/12 by XREAL_1:102,A1;
  1<=f by A1,NAT_1:14;
  then 24*1 <= 96*f by XREAL_1:66;
  then 24*1 *k^2 <= 96*f *k^2 by XREAL_1:64;
  then
A120: 24*1 *k^2 <= W by A118,XXREAL_0:2;
A121: 1*k^2 <= 24*k^2 by XREAL_1:64;
  2*k^2 <= 24*k^2 by XREAL_1:64;
  then 2* k^2 <= W*1 by A120,XXREAL_0:2;
  then
A122: k^2/W <=1/2 by XREAL_1:102,A1;
  k * U|^k *1 <= k * U|^k * f by A1,NAT_1:14,XREAL_1:64;
  then k * U|^k *1 *120 <= k * U|^k * f * 240 by XREAL_1:66;
  then 12*(((U|^k) * 10 *k)) <= 1*M by A117,XXREAL_0:2;
  then
A123: (((U|^k) * 10 *k))/M <=1/12 by XREAL_1:102;
A124: 1*(u|^3*W|^3)<= 100*(u|^3*W|^3) by XREAL_1:64;
  W*W*1 <= W|^3 by A54,A1,NAT_1:14,XREAL_1:64;
  then W*W * u <= W|^3 * (u|^3) < U by A58,XREAL_1:66,NAT_1:13,A124;
  then W*(W * W|^k) <= U by XXREAL_0:2;
  then
A125: W*( W|^(k+1)) <= U by NEWTON:6;
  1<= k*(k+1) by A1,NAT_1:14;
  then 96*1<= k*(k+1)*100 by XREAL_1:66;
  then 96*1*f <= k*(k+1)*100*f by XREAL_1:64;
  then 96*f *( W|^(k+1)) <= W*( W|^(k+1)) by XREAL_1:64;
  then 12* (8*f*W|^(k+1)) <=1 *U by A125,XXREAL_0:2;
  then
A126: (8*f*W|^(k+1))/ U<=1/12 by XREAL_1:102;
  1<= f*k*(k+1) by A1,NAT_1:14;
  then 1*24 <= 100*(f*k*(k+1)) by XREAL_1:66;
  then 24*( W|^(k+1)) <= W*( W|^(k+1)) by XREAL_1:64;
  then 12*(2* W|^(k+1)) <= U*1 by A125,XXREAL_0:2;
  then (2* W|^(k+1)) /U <=1/12 by XREAL_1:102;
  then 2* (W|^(k+1) /U) <=1/12 by XCMPLX_1:74;
  then
A127:2*((W|^(k+1)) * (1/U)) <= 1/12 by XCMPLX_1:99;
A128: 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M <= 1/12+1/12 = 1/6 <=1/2
    by A127,A123,XREAL_1:7;
  then
A129: 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M <= 1/2 by XXREAL_0:2;
A130: 2* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) <= 2*(1/6)<=1
    by A128,XREAL_1:64;
A131: 2* ( 2*(W|^(k+1)) * (1/U)+(((U|^k) * 10 *k))/M)<=1 by A130,XXREAL_0:2;
A132: (U+1)/U = U/U +1/U by XCMPLX_1:62
  .= 1+I*(1/U) by XCMPLX_1:60;
  1/U <= 1/(2*W) by A66,XREAL_1:118,A1;
  then consider T8 be _Theta such that
A133:  (1+I*(1/U))|^W = 1+ T8*2*W* (1/U) by Th9;
A134: ((U+1) |^W) / (U|^Wk) = (U|^k) * (((U+1) |^W) / ((U|^Wk) * (U|^k)))
  by XCMPLX_1:92
  .= (U|^k) * (((U+1) |^W) / ((U|^ (Wk+k)))) by NEWTON:8
  .= (U|^k) * (1+ T8*2*W* (1/U)) by A133,A132,PREPOWER:8;
A135:|. 2 .| = 2;
A136: (2*W)/U <=1 by XREAL_1:183,A66;
  then
A137: -((2*W)/U) >= -1 by XREAL_1:24;
  -1<= T8<=1 by Def1;
  then (-1)*((2*W)/U)<= T8*((2*W)/U)<=1 *((2*W)/U) by XREAL_1:64;
  then -1 <= T8*((2*W)/U)<= 1 by A136,A137,XXREAL_0:2;
  then
A138: -1+1 <= T8*((2*W)/U)+1<= 1+1 by XREAL_1:6;
A139:(2*W)* (1/U) = (2*W)/U by XCMPLX_1:99;
  then |.(1+ T8*2*W* (1/U)).| = (1+ T8*2*W* (1/U)) by A138,ABSVALUE:def 1;
  then consider T9 be _Theta such that
A140: T7* (1+ T8*2*W* (1/U)) = T9*2 by Th2,A135,A138,A139;
A141:  (U|^k) * (1+ T8*2*W* (1/U)) * (T7* ((5*k)/M)) =
  (U|^k) * ((1+ T8*2*W* (1/U)) * T7)* ((5*k)/M)
  .= (U|^k) * (2*T9)* ((5*k)/M) by A140
  .= T9 * ( ((U|^k) * 2) * ((5*k)/M))
  .= T9 * ((((U|^k) * 2) * (5*k))/M) by XCMPLX_1:74;
A142: (1/ (U|^(Wk+1))) * U = (1/ (U* U|^Wk)) * U by NEWTON:6
  .= 1/ (U|^Wk) by XCMPLX_1:92;
A143: D*U = U*((1/ (U|^(Wk+1)))* Sum IWW) by RVSUM_1:87;
  IWW<>{} by A16;
  then consider iww be FinSequence of REAL,x be Element of REAL such that
A144: IWW = <*x*>^iww by FINSEQ_2:130;
  1<= Wk+1 by NAT_1:11;
  then (W choose(k+0))*(U|^(W-'(k+0)))=IWW.(0+1) by A44,A15,A2,A14,FINSEQ_3:25
  .= x by A144;
  then
A145: x = (W choose k) * (U |^Wk) by A3,XXREAL_0:2,XREAL_1:233;
  Wk>0 by A105,XREAL_1:50;
  then reconsider Wk1=Wk-1 as Nat;
A146: len <*x*> = 1 by FINSEQ_1:40;
  then Wk+1 = 1 +len iww by A144,A15,A2,A14,FINSEQ_1:22;
  then
A147: len iww = W-(k+1)+1;
  for i be Nat st i+1 in dom iww holds iww.(i+1) =
    (W choose ((k+1)+i)) * (U |^(W-'((k+1)+i)))
  proof
    let i be Nat such that
A148: i+1 in dom iww;
    iww.(i+1) = IWW.(1+(i+1)) by A144,A146,A148,FINSEQ_1:def 7
     .= (W choose (k+(i+1))) * (U |^(W-'(k+(i+1))))
       by A44,FINSEQ_1:28,A148,A144,A146;
    hence thesis;
  end;
  then
A149: 0 < Sum iww  < 2*(W|^(k+1)) * (U|^(W-'(k+1))) by Th14,A104,A75,A147;
A150: (1/ (U|^Wk)) *x = (1/ (U|^Wk)) * (U |^Wk) * (W choose k) by A145
  .=1 * (W choose k) by XCMPLX_1:87;
  Sum IWW = x+ Sum iww by A144,RVSUM_1:76;
  then
A151: D*U = (W choose k) + (1/ (U|^Wk))*Sum iww by A143,A142,A150;
A152: W-'(k+1) = W-(k+1) = Wk1 by A6,A4,XXREAL_0:2,XREAL_1:233;
  Wk = Wk1+1;
  then
A153:(1/(U|^Wk))*(U|^(W-'(k+1)))=1/(U*U|^Wk1)*(U|^Wk1) by A152,NEWTON:6
  .= 1/U by XCMPLX_1:92;
  (1/ (U|^Wk))*Sum iww < (1/ (U|^Wk))* (2*(W|^(k+1)) * (U|^(W-'(k+1))))
    by A149, XREAL_1:68;
  then consider T10 be _Theta such that
A154: I*((1/ (U|^Wk))*Sum iww)=T10*(2*(W|^(k+1))*(1/U)) by A153,A149,Th5;
A155: (Wk+k) choose k >= Wk+1 > Wk by NAT_1:13,14,A1,RAMSEY_1:11;
  then W choose k >=1 by NAT_1:14;
  then reconsider T12 = 1/ (W choose k) as _Theta by Def1,XREAL_1:183;
A156: (W choose k) * T12 = 1 by XCMPLX_1:87,A155;
  consider T11 be _Theta such that
A157: T10* (2*(W|^(k+1)) * (1/U)) + T9 * ((((U|^k) * 10 *k))/M) =
  T11* ( 2*(W|^(k+1))* (1/U) + (((U|^k) * 10 *k))/M) by Th6;
  (Z+D)*U = ((U+1) |^W) / (U|^Wk*U) * U by A103,NEWTON:6
  .= ((U+1) |^W) / (U|^Wk) by XCMPLX_1:92;
  then
A158: r/(S*T) - m*U = D*U+(((U+1) |^W)/(U|^Wk)) *(T7*((5*k)/M)) by A101
  .= (W choose k) + T10* (2*(W|^(k+1)) * (1/U)) + T9 * ((((U|^k) * 10 *k))/M)
  by A151,A154,A141,A134
  .= (W choose k) + T11* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) by A157
  .= (W choose k) + (W choose k) * T12 * T11*
  ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) by A156
  .= (W choose k) *(1+ (T12*T11)*
  ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M));
  consider  T131 be _Theta such that
A159: W choose k = W|^k / (k!) * (1+T131*(k^2/W))
  by A121,A120,XXREAL_0:2,Th8;
  consider T13 be _Theta such that
A160: 1 / (1+T131*(k^2/W)) = 1+T13*2*(k^2/W) by Th7,A122;
A161: 1 / (W|^k / (k!) * (1+T131*(k^2/W))) =
  (1 / (W|^k / (k!))) * ( 1/ (1+T131*(k^2/W))) by XCMPLX_1:102
  .= (k!  / (W|^k)) * ( 1/ (1+T131*(k^2/W))) by XCMPLX_1:57;
  consider T14 be _Theta such that
A162: 1 / (1+(T12*T11)* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M)) =
    1+T14*2* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) by Th7,A129;
A163: k!  / (W|^k) * W|^k = k! by XCMPLX_1:87,A1;
  consider T15 be _Theta such that
A164: ( 1+T14*(2* ( 2*(W|^(k+1))*(1/U) + (((U|^k) * 10 *k))/M)) ) *
  ( 1+T13*(2*(k^2/W)))
  = 1 + T15 * ( 2* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) +
  2* (2*(k^2/W)) ) by A131,Th3;
A165: 1 * (u / (r/(S*T) - m*U)) = (1 / (r/(S*T) - m*U)) * 1 *u
  by XCMPLX_1:101
  .= ( 1 / (W choose k)) * ( 1+T14*2* ( 2*(W|^(k+1)) * (1/U) +
  (((U|^k) * 10 *k))/M) )* u by A162,A158,XCMPLX_1:102
  .= k! * (( 1+T13*(2*(k^2/W))) * ( 1+T14*(2* ( 2*(W|^(k+1)) * (1/U) +
  (((U|^k) * 10 *k))/M)) )) by A160,A163,A159,A161
  .= k! * (1 + T15 * ( 2* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) +
  2* (2*(k^2/W)))) by A164;
  -f <=0;
  then k! -f*2+2*f<= 0+2*f by A1,XREAL_1:6;
  then reconsider T16= k!/(2*f) as _Theta by Def1,XREAL_1:183;
A166: (2*f) * ( 2* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) +
  2* (2*(k^2/W)))
  = (8*f*(W|^(k+1))) * (1/U) + (2*f)*(2*(  (((U|^k) * 10 *k))/M)) +
  (2*f)*(2* (2*(k^2/W)))
  .= (8*f*W|^(k+1))/ U + (4*f* (((U|^k) * 10 *k)/M)) + (8*f*(k^2/W))
  by XCMPLX_1:99
  .= (8*f*W|^(k+1))/ U + ( ( 4*f)* ((U|^k) * 10 *k))/M + (8*f*(k^2/W))
  by XCMPLX_1:74
  .= (8*f*W|^(k+1))/ U + ( 40*f *(U|^k)*k)/M + (8*f*k^2)/W by XCMPLX_1:74;
  k! = T16*(2*f) by XCMPLX_1:87,A1;
  then
A167:  u / (r/(S*T) - m*U)
  = k!+ (T15* T16)*((2*f) * ( 2* ( 2*(W|^(k+1)) * (1/U) +
  (((U|^k) * 10 *k))/M) + 2* (2*(k^2/W)))) by A165
  .= k!+ (T15* T16)*((8*f*W|^(k+1))/ U+(40*f*(U|^k)*k)/M+(8*f*k^2)/W)by A166;
  6*( 40*f *(U|^k)*k) < 1*M by A116,XXREAL_0:2,A115;
  then
A168: ( 40*f *(U|^k)*k)/M < 1/6 by XREAL_1:106;
  (8*f*W|^(k+1))/ U + (8*f*k^2)/W <= (1/12) +(1/12) by A119,A126,XREAL_1:7;
  then
A169: (8*f*W|^(k+1))/ U + (8*f*k^2)/W + (40*f *(U|^k)*k)/M <
  (1/12) +(1/12)+(1/6) by A168,XREAL_1:8;
  -1 <= (T15* T16)<=1 by Def1;
  then (1/3) *(-1) < (-1) * ( (8*f*W|^(k+1))/ U +
  ( 40*f *(U|^k)*k)/M + (8*f*k^2)/W ) <=
  (T15* T16)*( (8*f*W|^(k+1))/ U + ( 40*f *(U|^k)*k)/M + (8*f*k^2)/W )
  <= 1 *( (8*f*W|^(k+1))/ U + ( 40*f *(U|^k)*k)/M + (8*f*k^2)/W ) < 1/3
  by A169,XREAL_1:64,69;
  then (1/3) *(-1) < (T15* T16)*( (8*f*W|^(k+1))/ U + ( 40*f *(U|^k)*k)/M
    + (8*f*k^2)/W ) < 1/3 by XXREAL_0:2;
  then -1/2 <  u / (r/(S*T) - m*U)-f < 1/2 by A1,A167, XXREAL_0:2;
  then (u /(r/(S*T) - m*U)-f)^2 < (1/2)^2 = (1/2)*(1/2) by SQUARE_1:def 1,50;
  then
A170: (u / (r/(S*T) - m*U)-f)* (u / (r/(S*T)-m*U)-f)<1/4 by SQUARE_1:def 1;
  set R = r - m*S*T*U;
A171:R<>0
  proof
    assume R=0; then
A172: r/(S*T) = (m*U*(S*T))/(S*T)
    .= m*U * ((S*T)/(S*T)) by XCMPLX_1:74
    .= m*U * 1 by XCMPLX_1:60;
A173: - (2*(W|^(k+1))*(1/U) + (((U|^k)*10*k))/M)>=-1/2
    by A129,XREAL_1:24;
    -1 <= (T12*T11) by Def1;
    then (-1) *( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M) <=
    (T12*T11)*( 2*(W|^(k+1))*(1/U)+(((U|^k)*10*k))/M) by XREAL_1:64;
    then -1/2 <= (T12*T11)* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M)
    by A173,XXREAL_0:2;
    then -1/2+1 <= (T12*T11)* ( 2*(W|^(k+1)) * (1/U) + (((U|^k) * 10 *k))/M)+1
    by XREAL_1:6;
    hence thesis by A158,XCMPLX_1:87,A155,A172;
  end;
A174: u^2 = u*u & S^2=S*S & R^2 = R*R & T^2=T*T & f^2=f*f by SQUARE_1:def 1;
A175: (u*S*T-f*R)/R = (u*S*T)/R-(f*R)/R by XCMPLX_1:120
  .=(u*(S*T))/R-f by A171,XCMPLX_1:89
  .= (u/(R/(S*T)))-f by XCMPLX_1:77
  .= (u/(r/(S*T)-((m*U)*(S*T))/(S*T)))-f by XCMPLX_1:120
  .= (u/(r/(S*T)-m*U)) -f by XCMPLX_1:89;
  ((u*S*T-f*R)/R) * ((u*S*T-f*R)/R)*4 <1/4 *4
    by XREAL_1:68,A170,A175;
  then ((u*S*T-f*R)/R) * ((u*S*T-f*R)/R)*4 *(R*R) <1 *(R*R) by A171,XREAL_1:68;
  then ((u*S*T-f*R)/R*R) * ((u*S*T-f*R)/R*R)*4 <1 *(R*R);
  then ((u*S*T-f*R)/R*R) * (u*S*T-f*R) *4 < R*R by A171, XCMPLX_1:87;
  then (u*S*T-f*R) * (u*S*T-f*R) *4 < R*R by A171, XCMPLX_1:87;
  then (u^2)*(S^2)*(T^2)*4 - 8 * (u*S*T)*(f*R) +
  4 * (f^2)*(R^2)+8 * (u*S*T)*(f*R)
  < R^2 + 8 * (u*S*T)*(f*R) by A174,XREAL_1:6;
  then
A176:(u^2)*(S^2)*(T^2)*4 - 8 * (u*S*T)*(f*R) + 4 * (f^2)*(R^2)+
     8 *(u*S*T)*(f*R) - R^2 < R^2 + 8 * (u*S*T)*(f*R)-R^2 by XREAL_1:14;
  take m,r,s,t,u,W,U,S,T,Q,M;
  thus thesis by A1,A176,Th12,A36,A38,A41,A43;
end;
