 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
A c= Z & (for x st x in Z holds f.x=cos.(1/x)/(x^2*(sin.(1/x))^2))
& Z c= dom (cosec*((id Z)^)) & Z = dom f & f|A is continuous
implies integral(f,A)=(cosec*((id Z)^)).(upper_bound A)-
(cosec*((id Z)^)).(lower_bound A)
proof
  assume
A1:A c= Z & (for x st x in Z holds f.x=cos.(1/x)/(x^2*(sin.(1/x))^2))
   & Z c= dom (cosec*((id Z)^)) & Z = dom f & f|A is continuous;
 then
A2:f is_integrable_on A & f|A is bounded by INTEGRA5:10,11;
A3:Z c= dom ((id Z)^) by A1,FUNCT_1:101;
A4:not 0 in Z
   proof
     assume A5: 0 in Z;
     dom ((id Z)^) = dom id Z \ (id Z)"{0} by RFUNCT_1:def 2
                  .= dom id Z \ {0} by Lm1,A5; then
     not 0 in {0} by A5,A3,XBOOLE_0:def 5;
     hence thesis by TARSKI:def 1;
   end;
then A6:(cosec*((id Z)^)) is_differentiable_on Z by A1,FDIFF_9:9;
A7:for x being Element of REAL
   st x in dom ((cosec*((id Z)^))`|Z) holds ((cosec*((id Z)^))`|Z).x=f.x
 proof
   let x be Element of REAL;
   assume x in dom ((cosec*((id Z)^))`|Z);then
A8:x in Z by A6,FDIFF_1:def 7;then
((cosec*((id Z)^))`|Z).x = cos.(1/x)/(x^2*(sin.(1/x))^2) by A1,A4,FDIFF_9:9
                        .=f.x by A1,A8;
  hence thesis;
  end;
  dom ((cosec*((id Z)^))`|Z)=dom f by A1,A6,FDIFF_1:def 7;
  then ((cosec*((id Z)^))`|Z)= f by A7,PARTFUN1:5;
  hence thesis by A1,A2,A6,INTEGRA5:13;
end;
