reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence,
  p,p1,p2,q for Point of TOP-REAL 2;

theorem Th16:
  for f,a,b,c st (ex C be Subset of TOP-REAL 2 st (C
is_a_component_of (L~f)` & a in C & b in C)) & (ex C be Subset of TOP-REAL 2 st
  (C is_a_component_of (L~f)` & b in C & c in C)) holds ex C be Subset of
  TOP-REAL 2 st C is_a_component_of (L~f)` & a in C & c in C
proof
  let f be non constant standard special_circular_sequence, a,b,c such that
A1: ex C be Subset of TOP-REAL 2 st C is_a_component_of (L~f)` & a in C
  & b in C and
A2: ex C be Subset of TOP-REAL 2 st C is_a_component_of (L~f)` & b in C
  & c in C;
  per cases by A1,Th14;
  suppose
A3: a in RightComp f & b in RightComp f;
    now
      per cases by A2,Th14;
      suppose
A4:     b in RightComp f & c in RightComp f;
        RightComp f is_a_component_of (L~f)` by GOBOARD9:def 2;
        hence thesis by A3,A4;
      end;
      suppose
        b in LeftComp f & c in LeftComp f;
        then LeftComp f meets RightComp f by A3,XBOOLE_0:3;
        hence thesis by GOBRD14:14;
      end;
    end;
    hence thesis;
  end;
  suppose
A5: a in LeftComp f & b in LeftComp f;
    now
      per cases by A2,Th14;
      suppose
A6:     b in LeftComp f & c in LeftComp f;
        LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
        hence thesis by A5,A6;
      end;
      suppose
        b in RightComp f & c in RightComp f;
        then LeftComp f meets RightComp f by A5,XBOOLE_0:3;
        hence thesis by GOBRD14:14;
      end;
    end;
    hence thesis;
  end;
end;
