reserve p,p1,p2,p3,q for Point of TOP-REAL 2;
reserve n for Nat;

theorem Th16:
  for P being non empty Subset of TOP-REAL n, g being Function of
  I[01], (TOP-REAL n) st g is continuous one-to-one & rng g = P ex f being
  Function of I[01],(TOP-REAL n)|P st f=g & f is being_homeomorphism
proof
  let P be non empty Subset of TOP-REAL n, g be Function of I[01], TOP-REAL n;
  assume that
A1: g is continuous one-to-one and
A2: rng g = P;
  the carrier of (TOP-REAL n)|P = [#]((TOP-REAL n)|P);
  then
A3: the carrier of (TOP-REAL n)|P = P by PRE_TOPC:def 5;
  then reconsider f=g as Function of I[01],(TOP-REAL n)|P by A2,FUNCT_2:6;
  take f;
  thus f = g;
A4: [#]((TOP-REAL n)|P)= P by PRE_TOPC:def 5;
A5: dom f = the carrier of I[01] by FUNCT_2:def 1
    .= [#]I[01];
A6: [#]TOP-REAL n<>{};
  for P2 being Subset of (TOP-REAL n)|P st P2 is open holds f"P2 is open
  proof
    let P2 be Subset of (TOP-REAL n)|P;
    assume P2 is open;
    then consider C being Subset of TOP-REAL n such that
A7: C is open and
A8: C /\ [#]((TOP-REAL n)|P) = P2 by TOPS_2:24;
    g"P = [#]I[01] by A3,A5,RELSET_1:22;
    then f"P2 = f"C /\ [#]I[01] by A4,A8,FUNCT_1:68
      .= f"C by XBOOLE_1:28;
    hence thesis by A1,A6,A7,TOPS_2:43;
  end;
  then
A9: f is continuous by A4,TOPS_2:43;
  rng f = [#]((TOP-REAL n)|P) by A2,PRE_TOPC:def 5;
  hence thesis by A1,A9,COMPTS_1:17;
end;
