reserve r,r1,r2,g,g1,g2,x0,t for Real;
reserve n,k,m for Element of NAT;
reserve seq for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem
  f1 is_divergent_to+infty_in x0 & (for r1,r2 st r1<x0 & x0<r2 ex g1,g2
st r1<g1 & g1<x0 & g1 in dom(f1+f2) & g2<r2 & x0<g2 & g2 in dom(f1+f2)) & (ex r
  st 0<r & f2|(].x0-r,x0.[ \/ ].x0,x0+r.[) is bounded_below ) implies f1+f2
  is_divergent_to+infty_in x0
proof
  assume that
A1: f1 is_divergent_to+infty_in x0 and
A2: for r1,r2 st r1<x0 & x0<r2 ex g1,g2 st r1<g1 & g1<x0 & g1 in dom(f1+
  f2) & g2<r2 & x0<g2 & g2 in dom(f1+f2);
  given r such that
A3: 0<r and
A4: f2|(].x0-r,x0.[ \/ ].x0,x0+r.[) is bounded_below;
  now
    let s be Real_Sequence;
    assume that
A5: s is convergent and
A6: lim s=x0 and
A7: rng s c=dom(f1+f2)\{x0};
    consider k such that
A8: for n st k<=n holds x0-r<s.n & s.n<x0+r by A3,A5,A6,Th7;
    rng(s^\k)c=rng s by VALUED_0:21;
    then
A9: rng(s^\k)c=dom(f1+f2)\{x0} by A7;
    then
A10: rng(s^\k)c=dom f1\{x0} by Lm4;
A11: rng(s^\k)c=dom f2 by A9,Lm4;
    now
      consider r1 be Real such that
A12:  for g being object st g in (].x0-r,x0.[\/].x0,x0+r.[)/\dom f2
      holds r1<=f2.g by A4,RFUNCT_1:71;
      take r2=r1-1;
      let n be Nat;
A13:   n in NAT by ORDINAL1:def 12;
A14:  k<=n+k by NAT_1:12;
      then s.(n+k)<x0+r by A8;
      then
A15:  (s^\k).n<x0+r by NAT_1:def 3;
      x0-r<s.(n+k) by A8,A14;
      then x0-r<(s^\k).n by NAT_1:def 3;
      then (s^\k).n in {g2: x0-r<g2 & g2<x0+r} by A15;
      then
A16:  (s^\k).n in ].x0-r,x0+r.[ by RCOMP_1:def 2;
A17:  (s^\k).n in rng(s ^\k) by VALUED_0:28;
      then not (s^\k).n in {x0} by A9,XBOOLE_0:def 5;
      then (s^\k).n in ].x0-r,x0+r.[\{x0} by A16,XBOOLE_0:def 5;
      then (s^\k).n in ].x0-r,x0.[\/].x0,x0+r.[ by A3,Th4;
      then (s^\k).n in (].x0-r,x0.[\/].x0,x0+r.[)/\dom f2 by A11,A17,
XBOOLE_0:def 4;
      then r1-1<f2.((s^\k).n)-0 by A12,XREAL_1:15;
      hence r2<(f2/*(s^\k)).n by A11,FUNCT_2:108,A13;
    end;
    then
A18: f2/*(s^\k) is bounded_below by SEQ_2:def 4;
    lim(s^\k)=x0 by A5,A6,SEQ_4:20;
    then f1/*(s^\k) is divergent_to+infty by A1,A5,A10;
    then
A19: f1/*(s^\k)+f2/*(s^\k) is divergent_to+infty by A18,LIMFUNC1:9;
A20: rng s c=dom(f1+f2) by A7,Lm4;
    rng(s^\k)c=dom(f1+f2) by A9,Lm4;
    then rng(s^\k)c=dom f1/\dom f2 by VALUED_1:def 1;
    then f1/*(s^\k)+f2/*(s^\k)=(f1+f2)/*(s^\k) by RFUNCT_2:8
      .=((f1+f2)/*s)^\k by A20,VALUED_0:27;
    hence (f1+f2)/*s is divergent_to+infty by A19,LIMFUNC1:7;
  end;
  hence thesis by A2;
end;
