reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);

theorem Th16:
  for D be non empty set, A be Matrix of n,m,D, B be Matrix of n,k
  ,D for i st i in Seg width A holds Col(A^^B,i) = Col(A,i)
proof
  let D be non empty set, A be Matrix of n,m,D, B be Matrix of n,k,D;
  let i such that
A1: i in Seg width A;
  set AB=A^^B;
A2: len AB=n by MATRIX_0:def 2;
A3: len A=n by MATRIX_0:def 2;
  now
    let j such that
A4: j in Seg n;
    n<>0 by A4;
    then width AB=width A+width B by MATRIX_0:23;
    then width A<=width AB by NAT_1:11;
    then
A5: Seg width A c= Seg width AB by FINSEQ_1:5;
A6: dom A=Seg n by A3,FINSEQ_1:def 3;
A7: dom Line(A,j)=Seg width A by FINSEQ_2:124;
    dom AB=Seg n by A2,FINSEQ_1:def 3;
    hence Col(AB,i).j = AB*(j,i) by A4,MATRIX_0:def 8
      .= Line(AB,j).i by A1,A5,MATRIX_0:def 7
      .= (Line(A,j)^Line(B,j)).i by A4,Th15
      .= Line(A,j).i by A1,A7,FINSEQ_1:def 7
      .= A*(j,i) by A1,MATRIX_0:def 7
      .= Col(A,i).j by A4,A6,MATRIX_0:def 8;
  end;
  hence thesis by A3,A2,FINSEQ_2:119;
end;
