reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem
  i in dom R implies Sum lmlt(Line(1.(K,len R),i),R) = R/.i
proof
  set ONE=1.(K,len R);
  set L=Line(ONE,i);
  set M=lmlt(L,R);
A1: width ONE=len R by MATRIX_0:24;
  len L=width ONE by CARD_1:def 7;
  then dom L=dom R by A1,FINSEQ_3:29;
  then
A2: dom M=dom R by MATRLIN:12;
  then
A3: len M=len R by FINSEQ_3:29;
  consider f be sequence of  the carrier of V1 such that
A4: Sum M= f.(len M) and
A5: f.0 = 0.V1 and
A6: for j be Nat, v1 st j < len M & v1 = M.(j + 1) holds f.(
  j + 1) = f.j + v1 by RLVECT_1:def 12;
  defpred Q[Nat] means $1<=len M implies f.$1=R/.i;
  defpred P[Nat] means $1<i implies f.$1=0.V1;
  assume
A7: i in dom R;
  then
A8: 1<=i by FINSEQ_3:25;
  len ONE=len R by MATRIX_0:24;
  then
A9: dom R=dom ONE by FINSEQ_3:29;
A10: for n st i<=n holds Q[n] implies Q[n+1]
  proof
    let n such that
A11: i <=n;
    set n1=n+1;
A12: i<n1 by A11,NAT_1:13;
    reconsider N=n as Element of NAT by ORDINAL1:def 12;
    assume
A13: Q[n];
    assume
A14: n1<=len M;
    then
A15: n<len M by NAT_1:13;
A16: 1<=n1 by NAT_1:11;
    then n1 in Seg len R by A3,A14;
    then L.n1=ONE*(i,n1) & [i,n1] in Indices ONE by A7,A1,A9,MATRIX_0:def 7
,ZFMISC_1:87;
    then
A17: L.n1=0.K by A12,MATRIX_1:def 3;
A18: n1 in dom R by A2,A14,A16,FINSEQ_3:25;
    then R.n1=R/.n1 by PARTFUN1:def 6;
    then M.n1 = 0.K * R/.n1 by A2,A18,A17,FUNCOP_1:22
      .= 0.V1 by VECTSP_1:14;
    hence f.n1 = f.N + 0.V1 by A6,A15
      .= R/.i by A13,A14,NAT_1:13,RLVECT_1:def 4;
  end;
A19: i<=len M by A7,A2,FINSEQ_3:25;
A20: for n st P[n] holds P[n+1]
  proof
    let n such that
A21: P[n];
    reconsider N=n as Element of NAT by ORDINAL1:def 12;
    set n1=n+1;
    assume
A22: n1<i;
    then n1<len M by A19,XXREAL_0:2;
    then
A23: n<len M by NAT_1:13;
A24: 1<=n1 & n1<=len R by A19,A3,A22,NAT_1:11,XXREAL_0:2;
    then n1 in Seg len R;
    then L.n1=ONE*(i,n1) & [i,n1] in Indices ONE by A7,A1,A9,MATRIX_0:def 7
,ZFMISC_1:87;
    then
A25: L.n1=0.K by A22,MATRIX_1:def 3;
A26: n1 in dom R by A24,FINSEQ_3:25;
    then R.n1=R/.n1 by PARTFUN1:def 6;
    then M.n1 = 0.K * R/.n1 by A2,A26,A25,FUNCOP_1:22
      .= 0.V1 by VECTSP_1:14;
    hence f.n1 = f.N + 0.V1 by A6,A23
      .= 0.V1 by A21,A22,NAT_1:13,RLVECT_1:def 4;
  end;
A27: P[0] by A5;
A28: for n holds P[n] from NAT_1:sch 2(A27,A20);
A29: Q[i]
  proof
    i in Seg len R by A8,A19,A3;
    then L.i=ONE*(i,i) & [i,i] in Indices ONE by A7,A1,A9,MATRIX_0:def 7
,ZFMISC_1:87;
    then
A30: L.i=1_K by MATRIX_1:def 3;
    reconsider i1=i-1 as Element of NAT by A8,NAT_1:21;
A31: i1+1=i;
    then i1<i by NAT_1:13;
    then
A32: f.i1=0.V1 by A28;
    assume i<=len M;
    then
A33: i1<len M by A31,NAT_1:13;
    R.i=R/.i by A7,PARTFUN1:def 6;
    then M.i = 1_K * R/.i by A7,A2,A30,FUNCOP_1:22
      .= R/.i;
    then f.(i1+1) = f.i1+R/.i by A6,A33;
    hence thesis by A32,RLVECT_1:def 4;
  end;
  for n st i<=n holds Q[n] from NAT_1:sch 8(A29,A10);
  hence thesis by A19,A4;
end;
