
theorem
for H be Subset of RNS_Real, I be open_interval Subset of REAL
 st H = I holds H is open
proof
    let H be Subset of RNS_Real, I be open_interval Subset of REAL;
    assume
A1:  H = I;

    for x be Point of RNS_Real st x in H holds
     ex N be Neighbourhood of x st N c= H
    proof
     let x be Point of RNS_Real;
     assume
A2:  x in H;
     reconsider s = x as Real;
     reconsider s1 = s as R_eal by XXREAL_0:def 1;

     consider a,b be R_eal such that
A3:   I = ].a,b.[ by MEASURE5:def 2;

A4:  a < s & s < b by A1,A2,A3,XXREAL_1:4; then
     consider a1 be Real such that
A5:  a < a1 & a1 < s1 by INTEGR26:18;
     consider b1 be Real such that
A6:  s1 < b1 & b1 < b by A4,INTEGR26:18;

     set e = min(b1-s,s-a1);
A7:  a1 <= s-e & s+e <= b1 by XREAL_1:11,19,XXREAL_0:17;

     set N = { y where y is Point of RNS_Real : ||.y-x .|| < e};
     now let z be object;
      assume z in N; then
      ex y be Point of RNS_Real st z=y & ||.y-x .|| < e;
      hence z in the carrier of RNS_Real;
     end; then
     reconsider N as Subset of RNS_Real by TARSKI:def 3;

     0 < b1-s & 0 < s-a1 by A5,A6,XREAL_1:50; then
A8:  N is Neighbourhood of x by XXREAL_0:21,NFCONT_1:def 1;

     now let z be object;
      assume z in N; then
      consider y be Point of RNS_Real such that
A9:   z = y & ||. y-x .|| < e;
      reconsider h = y as Real;
      h-s = y-x by DUALSP03:4; then
      ||.y-x .|| = |.h-s.| by EUCLID:def 2; then
      h in ].s-e,s+e.[ by A9,RCOMP_1:1; then
      s-e < h & h < s+e by XXREAL_1:4; then
      a1 <= h & h <= b1 by A7,XXREAL_0:2; then
      a < h & h < b by A5,A6,XXREAL_0:2;
      hence z in H by A9,A1,A3;
     end; then
     N c= H;
     hence thesis by A8;
    end;
    hence H is open by NDIFF_1:4;
end;
