reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem Th16:
  for F st F is Cover of T ex G st G c= F & G is Cover of T & card
  G c= card [#]T
proof
  let F such that
A1: F is Cover of T;
  per cases;
  suppose
A2: F is empty;
    take F;
    thus thesis by A1,A2;
  end;
  suppose
A3: F is non empty;
    defpred P[object,object] means ex D2 being set st D2 = $2 & $1 in D2;
A4: for x be object st x in [#]T ex y be object st y in F & P[x,y]
    proof
      let x be object;
      assume x in [#]T;
      then x in union F by A1,SETFAM_1:45;
      then ex y be set st x in y & y in F by TARSKI:def 4;
      hence thesis;
    end;
    consider g be Function of[#]T,F such that
A5: for x be object st x in [#]T holds P[x,g.x] from FUNCT_2:sch 1(A4);
    reconsider R=rng g as Subset-Family of T by XBOOLE_1:1;
    take R;
A6: dom g=[#]T by A3,FUNCT_2:def 1;
    [#]T c=union R
    proof
      let x be object;
      assume
A7:     x in [#]T;
      then P[x,g.x] by A5;
      then x in g.x & g.x in R by A6,FUNCT_1:def 3,A7;
      hence thesis by TARSKI:def 4;
    end;
    hence thesis by A6,CARD_1:12,SETFAM_1:def 11;
  end;
end;
