reserve T, T1 for non empty TopSpace;
reserve F,G,H for Subset-Family of T,
  A,B,C,D for Subset of T,
  O,U for open Subset of T,
  p,q for Point of T,
  x,y,X for set;
reserve Un for FamilySequence of T,
  r,r1,r2 for Real,
  n for Element of NAT;

theorem
  for T st T is metrizable ex Un being FamilySequence of T st Un is
  Basis_sigma_locally_finite
proof
  let T;
  assume
A1: T is metrizable;
  then consider
  metr being Function of [:the carrier of T,the carrier of T:],REAL
  such that
A2: metr is_metric_of (the carrier of T) and
A3: Family_open_set( SpaceMetr (the carrier of T,metr)) = the topology
  of T;
  set PM = SpaceMetr(the carrier of T,metr);
  reconsider PM as non empty MetrSpace by A2,PCOMPS_1:36;
  deffunc BALL(Element of NAT)={Ball(x, 1/(2 |^ $1)) where x is Element of PM:
  x is Element of PM};
  defpred E[Element of NAT,set] means $2 = BALL($1);
A4: for k being Element of NAT ex y being Subset-Family of T st E[k,y]
  proof
    let k be Element of NAT;
    set Ak=BALL(k);
    Ak c= bool the carrier of T
    proof
      let B be object;
      assume B in Ak;
      then
      ex x being Element of PM st B=Ball(x,1/(2 |^ k)) & x is Element of PM;
      then B in Family_open_set(PM) by PCOMPS_1:29;
      hence thesis by A3;
    end;
    hence thesis;
  end;
  consider FB being sequence of bool bool (the carrier of T) such that
A5: for k being Element of NAT holds E[k,FB.k] from FUNCT_2:sch 3(A4);
  defpred P[object,object] means
  ex W being Subset-Family of T st W = $2 & W is open
  & W is Cover of T & W is_finer_than FB.$1 & W is locally_finite;
  set TPM = TopSpaceMetr PM;
A6: [#]T=[#]TPM by A2,PCOMPS_2:4;
A7: for n ex PP being Subset-Family of T st PP is_finer_than FB.n & PP is
  Cover of T & PP is open & PP is locally_finite
  proof
    let n;
    [#]TPM c= union (FB.n)
    proof
      let x be object;
      assume x in [#]TPM;
      then reconsider x9=x as Element of PM;
      dist(x9,x9) = 0 & 2|^n > 0 by METRIC_1:1,NEWTON:83;
      then dist(x9,x9)<1/(2|^n) by XREAL_1:139;
      then
A8:   x9 in Ball(x9,1/(2|^ n)) by METRIC_1:11;
      Ball(x9,1/(2|^ n)) in BALL(n);
      then Ball(x9,1/(2|^ n)) in FB.n by A5;
      hence thesis by A8,TARSKI:def 4;
    end;
    then
A9: FB.n is Cover of T by A6,SETFAM_1:def 11;
    for U being Subset of T holds U in (FB.n) implies U is open
    proof
      let U be Subset of T;
      assume U in (FB.n);
      then U in BALL(n) by A5;
      then ex x being Element of PM st U = Ball(x,1/(2|^ n)) & x is Element of
      PM;
      then U in the topology of T by A3,PCOMPS_1:29;
      hence thesis by PRE_TOPC:def 2;
    end;
    then (FB.n) is open by TOPS_2:def 1;
    then ex PP being Subset-Family of T st PP is open & PP is Cover of T & PP
    is_finer_than (FB.n) & PP is locally_finite by A1,A9,PCOMPS_2:6;
    hence thesis;
  end;
A10: for k being object st k in NAT
   ex y being object st y in bool bool the carrier of T & P[k,y]
  proof
    let k be object;
    assume k in NAT;
    then reconsider k as Element of NAT;
    ex PP being Subset-Family of T st PP is_finer_than FB.k & PP is Cover
    of T & PP is open & PP is locally_finite by A7;
    hence thesis;
  end;
  consider UC being FamilySequence of T such that
A11: for x  being object st x in NAT holds P[x,UC.x] from FUNCT_2:sch 1(A10);
A12: for A being Subset of T st A is open for p being Point of T st p in A
  ex B being Subset of T st B in Union UC & p in B & B c= A
  proof
    let A;
    assume A is open;
    then
A13: A in Family_open_set(PM) by A3,PRE_TOPC:def 2;
    let p;
    assume
A14: p in A;
    then reconsider p as Element of PM by A13;
    consider r1 such that
A15: r1>0 and
A16: Ball(p,r1) c=A by A14,A13,PCOMPS_1:def 4;
    consider n being Nat such that
A17: 1/(2|^ n)<=r1 by A15,PREPOWER:92;
A18: P[n+1,UC.(n+1)] by A11;
    then union (UC.(n+1)) = the carrier of T by SETFAM_1:45;
    then consider B being set such that
A19: p in B and
A20: B in (UC.(n+1)) by TARSKI:def 4;
    reconsider B as Subset of PM by A2,A20,PCOMPS_2:4;
    consider B1 being set such that
A21: B1 in FB.(n+1) and
A22: B c= B1 by A18,A20,SETFAM_1:def 2;
    B1 in BALL(n+1) by A5,A21;
    then consider q being Element of PM such that
A23: B1=Ball(q,(1/(2|^(n+1)))) and
    q is Element of PM;
A24: dist(q,p)<1/(2|^(n+1)) by A19,A22,A23,METRIC_1:11;
    now
      let r be Element of PM;
      assume r in B;
      then dist(q,r)<1/(2|^(n+1)) by A22,A23,METRIC_1:11;
      then
      dist(p,r)<=dist(q,p)+dist(q,r) & dist(q,p)+dist(q,r)<1/(2|^(n+1))+1
      /(2|^(n+1 )) by A24,METRIC_1:4,XREAL_1:8;
      then dist(p,r)<2*(1/(2|^(n+1))) by XXREAL_0:2;
      then dist(p,r)<(1/(2|^n * 2))*2 by NEWTON:6;
      then dist(p,r)<(1/(2|^n)) by XCMPLX_1:92;
      then dist(p,r)<r1 by A17,XXREAL_0:2;
      hence r in Ball(p,r1) by METRIC_1:11;
    end;
    then
A25: B c= Ball(p,r1);
    B in Union UC by A20,PROB_1:12;
    hence thesis by A16,A19,A25,XBOOLE_1:1;
  end;
  for n holds UC.n is locally_finite
  proof
    let n;
    P[n,UC.n] by A11;
    hence thesis;
  end;
  then
A26: UC is sigma_locally_finite;
  Union UC c= the topology of T
  proof
    let u be object;
    assume u in Union UC;
    then consider k being Nat such that
A27: u in UC.k by PROB_1:12;
A28:  k in NAT by ORDINAL1:def 12;
    reconsider u9=u as Subset of T by A27;
    P[k,UC.k] by A11,A28;
    then u9 is open by A27,TOPS_2:def 1;
    hence thesis by PRE_TOPC:def 2;
  end;
  then Union UC is Basis of T by A12,YELLOW_9:32;
  then UC is Basis_sigma_locally_finite by A26;
  hence thesis;
end;
