reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;

theorem Th16:
  for f be PartFunc of RNS,CNS, x0 be Point of RNS holds f
is_continuous_in x0 iff x0 in dom f & for N1 being Neighbourhood of f/.x0 ex N
  being Neighbourhood of x0 st for x1 be Point of RNS st x1 in dom f & x1 in N
  holds f/.x1 in N1
proof
  let f be PartFunc of RNS,CNS;
  let x0 be Point of RNS;
  thus f is_continuous_in x0 implies x0 in dom f & for N1 being Neighbourhood
of f/.x0 ex N being Neighbourhood of x0 st for x1 be Point of RNS st x1 in dom
  f & x1 in N holds f/.x1 in N1
  proof
    assume
A1: f is_continuous_in x0;
    hence x0 in dom f;
    let N1 be Neighbourhood of f/.x0;
    consider r such that
A2: 0<r and
A3: {y where y is Point of CNS : ||.y-f/.x0 .|| < r} c= N1 by Def1;
    consider s such that
A4: 0<s and
A5: for x1 be Point of RNS st x1 in dom f & ||. x1- x0 .|| <s holds
    ||. f/.x1- f/.x0 .|| <r by A1,A2,Th10;
    reconsider N={z where z is Point of RNS : ||.z-x0 .|| < s} as
    Neighbourhood of x0 by A4,NFCONT_1:3;
    take N;
    let x1 be Point of RNS;
    assume that
A6: x1 in dom f and
A7: x1 in N;
    ex z be Point of RNS st x1=z & ||.z-x0 .|| < s by A7;
    then ||. f/.x1- f/.x0 .|| <r by A5,A6;
    then f/.x1 in {y where y is Point of CNS : ||.y-f/.x0 .|| < r};
    hence thesis by A3;
  end;
  assume that
A8: x0 in dom f and
A9: for N1 being Neighbourhood of f/.x0 ex N being Neighbourhood of x0
  st for x1 be Point of RNS st x1 in dom f & x1 in N holds f/.x1 in N1;
  now
    let r;
    assume 0<r;
    then reconsider N1 = {y where y is Point of CNS : ||.y-f/.x0 .|| < r} as
    Neighbourhood of f/.x0 by Th2;
    consider N2 being Neighbourhood of x0 such that
A10: for x1 be Point of RNS st x1 in dom f & x1 in N2 holds f/.x1 in N1 by A9;
    consider s such that
A11: 0<s and
A12: {z where z is Point of RNS : ||.z-x0 .|| < s} c= N2 by NFCONT_1:def 1;
    take s;
    for x1 be Point of RNS st x1 in dom f & ||. x1- x0 .|| <s holds ||. f
    /.x1- f/.x0 .|| <r
    proof
      let x1 be Point of RNS;
      assume that
A13:  x1 in dom f and
A14:  ||. x1- x0 .|| <s;
      x1 in {z where z is Point of RNS : ||.z-x0 .|| < s} by A14;
      then f/.x1 in N1 by A10,A12,A13;
      then ex y be Point of CNS st f/.x1=y & ||.y-f/.x0 .|| < r;
      hence thesis;
    end;
    hence 0<s & for x1 be Point of RNS st x1 in dom f & ||. x1 - x0 .|| < s
    holds ||. f/.x1- f/.x0 .|| <r by A11;
  end;
  hence thesis by A8,Th10;
end;
