 reserve j for set;
 reserve p,r for Real;
 reserve S,T,F for RealNormSpace;
 reserve x0 for Point of S;
 reserve g for PartFunc of S,T;
 reserve c for constant sequence of S;
 reserve R for RestFunc of S,T;
 reserve G for RealNormSpace-Sequence;
 reserve i for Element of dom G;
 reserve f for PartFunc of product G,F;
 reserve x for Element of product G;

theorem LMOPN:
for S be RealLinearSpace, p,q be Point of S st p <> q
 holds ].p,q.[ = { p+t*(q-p) where t is Real : 0 < t & t < 1}
proof
   let S be RealLinearSpace, p,q be Point of S;
   assume AS1: p <> q;
   set A = { p+t*(q-p) where t is Real : 0 < t & t < 1};
   for x be object holds (x in ].p,q.[ iff x in A)
   proof
    let x be object;
    hereby assume x in ].p,q.[; then
P1:  x in [.p,q.] & not x in {p,q} by XBOOLE_0:def 5; then
     x in {(1-r)*p + r*q where r is Real : 0 <= r & r <= 1}
        by RLTOPSP1:def 2; then
     consider t be Real such that
P2:   x= (1-t)*p+t*q & 0 <= t & t <= 1;
P3:  x= p+t*(q-p) by P2,Lm2;
P4:  0 <> t
     proof
      assume t = 0; then
      x = p + 0.S  by P3,RLVECT_1:10
       .= p by RLVECT_1:4;
      hence contradiction by P1,TARSKI:def 2;
     end;

     1 <> t
     proof
      assume t = 1; then
      x = p + (q-p)  by P3,RLVECT_1:def 8
       .= q- (p - p) by RLVECT_1:29
       .= q - 0.S  by RLVECT_1:15
       .= q by RLVECT_1:13;
      hence contradiction by P1,TARSKI:def 2;
     end; then
     0 < t & t < 1 by P2,P4,XXREAL_0:1;
     hence x in A by P3;
    end;

    assume x in A; then
    consider t be Real such that
P4:  x= p+t*(q-p) &  0 < t & t < 1;
    x= (1-t)*p+t*q by Lm2,P4; then
    x in {(1-r)*p + r*q where r is Real : 0 <= r & r <= 1} by P4; then
P5: x in [.p,q.] by RLTOPSP1:def 2;
P6: x <> p
    proof
     assume x = p; then
P7:  0.S = t*(q-p) + p - p by P4,RLVECT_1:15
        .= t*(q-p) + (p-p) by RLVECT_1:28
        .= t*(q-p) + 0.S by RLVECT_1:15
        .= t*(q-p) by RLVECT_1:4;
     q-p <> 0.S by AS1,RLVECT_1:21;
     hence contradiction by P4,P7,RLVECT_1:11;
    end;
    x <> q
    proof
     assume x = q; then
     q-p = t*(q-p) + (p-p) by P4,RLVECT_1:28
        .=t*(q-p) + 0.S  by RLVECT_1:15
        .=t*(q-p) by RLVECT_1:4; then
     1*(q-p) = t*(q-p) by RLVECT_1:def 8; then
     1*(q-p) - t*(q-p) =0.S by RLVECT_1:15; then
P7:  (1-t)* (q-p) = 0.S by RLVECT_1:35;
     q-p <> 0.S by AS1,RLVECT_1:21; then
     1-t = 0 by RLVECT_1:11,P7;
     hence contradiction by P4;
    end; then
    not x in {p,q} by P6,TARSKI:def 2;
    hence x in ]. p,q .[ by P5,XBOOLE_0:def 5;
   end;
   hence thesis by TARSKI:2;
end;
