reserve X for set;
reserve a,b,c,k,m,n for Nat;
reserve i for Integer;
reserve r for Real;
reserve p for Prime;

theorem Th16:
  {n where n is non zero even Nat: n divides 2|^n+2 & n-1 divides 2|^n+1}
  is infinite
  proof
    set X =
    {n where n is non zero even Nat: n divides 2|^n+2 & n-1 divides 2|^n+1};
A1: 2 = 2*1;
    2|^2+2 = 2*3 by Lm2;
    then
A2: 2 divides 2|^2+2;
    2-1 divides 2|^2+1 by INT_2:12;
    then
A3: 2 in X by A1,A2;
A4: X is natural-membered
    proof
      let x be object;
      assume x in X;
      then ex n being non zero even Nat st x = n &
      n divides 2|^n+2 & n-1 divides 2|^n+1;
      hence thesis;
    end;
    for a st a in X ex b st b > a & b in X
    proof
      let a;
      assume a in X;
      then consider n being non zero even Nat such that
A5:   a = n and
A6:   n divides 2|^n+2 & n-1 divides 2|^n+1;
      take b = 2|^n+2;
A7:   n < 2|^n by NEWTON:86;
      2|^n <= 2|^n+2 by NAT_1:11;
      hence b > a by A5,A7,XXREAL_0:2;
      b-1 divides 2|^b+1 & b divides 2|^b+2 by A6,Th15;
      hence b in X;
    end;
    hence thesis by A3,A4,Th1;
  end;
