reserve a,b,c,k,m,n for Nat;
reserve p for Prime;

theorem
  {[x,y] where x,y is Nat: x,y satisfy_Sierpinski_problem_35} is infinite
  proof
    set A = {[x,y] where x,y is Nat: x,y satisfy_Sierpinski_problem_35};
    deffunc F(Nat) = [36*$1+14,(12*$1+5)*(18*$1+7)];
    consider f being ManySortedSet of NAT such that
A1: for d being Element of NAT holds f.d = F(d) from PBOOLE:sch 5;
A2: dom f = NAT by PARTFUN1:def 2;
A3: rng f c= A
    proof
      let y be object;
      assume y in rng f;
      then consider k being object such that
A4:   k in dom f and
A5:   f.k = y by FUNCT_1:def 3;
      reconsider k as Element of NAT by A4,PARTFUN1:def 2;
      36*k+14,(12*k+5)*(18*k+7) satisfy_Sierpinski_problem_35 by Th15;
      then F(k) in A;
      hence thesis by A1,A5;
    end;
    f is one-to-one
    proof
      let x1,x2 be object such that
A6:   x1 in dom f & x2 in dom f and
A7:   f.x1 = f.x2;
      reconsider x1,x2 as Element of NAT by A6,PARTFUN1:def 2;
      f.x1 = F(x1) & f.x2 = F(x2) by A1;
      then 36*x1+14 = 36*x2+14 by A7,XTUPLE_0:1;
      hence thesis;
    end;
    hence thesis by A2,A3,CARD_1:59;
  end;
