reserve x,x0,x1,y,y0,y1,z,z0,z1,r,r1,s,p,p1 for Real;
reserve u,u0 for Element of REAL 3;
reserve n for Element of NAT;
reserve s1 for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL 3,REAL;
reserve R,R1 for RestFunc;
reserve L,L1 for LinearFunc;

theorem Th16:
  u = <*x0,y0,z0*> & f is_hpartial_differentiable`31_in u implies
  hpartdiff31(f,u) = diff(SVF1(1,pdiff1(f,3),u),x0)
proof
    set r = hpartdiff31(f,u);
    assume that
A1: u = <*x0,y0,z0*> and
A2: f is_hpartial_differentiable`31_in u;
    consider x1,y1,z1 being Real such that
A3: u = <*x1,y1,z1*> & ex N being Neighbourhood of x1 st
    N c= dom SVF1(1,pdiff1(f,3),u) & ex L,R st for x st x in N holds
    SVF1(1,pdiff1(f,3),u).x - SVF1(1,pdiff1(f,3),u).x1 = L.(x-x1) + R.(x-x1)
    by A2;
    consider N being Neighbourhood of x1 such that
A4: N c= dom SVF1(1,pdiff1(f,3),u) & ex L,R st for x st x in N holds
    SVF1(1,pdiff1(f,3),u).x - SVF1(1,pdiff1(f,3),u).x1 = L.(x-x1) + R.(x-x1)
    by A3;
    consider L,R such that
A5: for x st x in N holds
    SVF1(1,pdiff1(f,3),u).x - SVF1(1,pdiff1(f,3),u).x1 = L.(x-x1) + R.(x-x1)
    by A4;
A6: x0 = x1 & y0 = y1 & z0 = z1 by A1,A3,FINSEQ_1:78;
A7: r = L.1 by A2,A3,A4,A5,Def16;
 SVF1(1,pdiff1(f,3),u) is_differentiable_in x0 by A4,A6,FDIFF_1:def 4;
    hence thesis by A4,A5,A6,A7,FDIFF_1:def 5;
end;
