
theorem Th16:
  for I being non empty set for i being Element of I for A be
PLS-yielding ManySortedSet of I for B being Block of A.i for P being Element of
  Carrier A holds product({P}+*(i,B)) is Block of Segre_Product A
proof
  let I being non empty set;
  let i be Element of I;
  let A be PLS-yielding ManySortedSet of I;
  let B being Block of A.i;
  let P being Element of Carrier A;
  reconsider PP={P} as ManySortedSubset of Carrier A by PENCIL_1:11;
  B in the topology of A.i;
  then reconsider B1=B as Subset of A.i;
A1: now
    let j be Element of I;
    assume j <> i;
    then {P}+*(i,B1).j = {P}.j by FUNCT_7:32;
    hence {P}+*(i,B1).j is 1-element by Th15;
  end;
  2 c= card B by PENCIL_1:def 6;
  then B1 is non trivial by PENCIL_1:4;
  then reconsider
  S=PP+*(i,B1) as Segre-like non trivial-yielding ManySortedSubset
  of Carrier A by A1,PENCIL_1:9,def 20,PENCIL_2:7;
A2: now
    assume indx(S)<>i;
    then S.indx(S) is 1-element by A1;
    hence contradiction by PENCIL_1:def 21;
  end;
  dom {P} = I by PARTFUN1:def 2;
  then S.indx(S) = B1 by A2,FUNCT_7:31;
  hence thesis by A2,PENCIL_1:24;
end;
