
theorem uniolinf:
  for X be finite set,Y be set holds
    Y is c=-linear & X c= union Y & Y <> {} implies
      ex Z be set st X c= Z & Z in Y
  proof
    let X be finite set,Y be set;
    assume
A0: Y is c=-linear & X c= union Y & Y <> {};
      deffunc G(object) = {y where y is Element of Y: $1 in y};
      deffunc F(object) = the Element of G($1);
A18: for x be object holds x in X implies G(x) is non empty
    proof
      let x be object;
      assume x in X;then
      consider y be set such that
A11:  x in y & y in Y by TARSKI:def 4,A0;
      reconsider y as Element of Y by A11;
      y in G(x) by A11;
      hence G(x) is non empty;
    end;
    per cases;
    suppose
S1:   X is empty;
      consider Z be object such that
A15:  Z in Y by A0,XBOOLE_0:def 1;
      consider Z1 be set such that
A16:  Z1 in Y & not ex x be object st x in Y & x in Z1 by TARSKI:3,A15;
      X c= Z1 by S1;
      hence thesis by A16;
    end;
    suppose
S2:   not X is empty;
      set Y1 = {F(x) where x is Element of X: x in X};
A20:  X is finite;
A2:   Y1 is finite from FRAENKEL:sch 21(A20);
A19:  Y1 c= Y
      proof
        let x be object;
        assume x in Y1;then
        consider x1 be Element of X such that
A13:    x = the Element of G(x1) & x1 in X;
        G(x1) is non empty by A18,A13;then
        x in G(x1) by A13;then
        consider x2 be Element of Y such that
A14:    x2 = x & x1 in x2;
        thus x in Y by A0,A14;
      end;
      Y1 <> {}
      proof
        consider x be object such that
A15:    x in X by XBOOLE_0:def 1,S2;
        consider x1 be set such that
A16:    x1 in X & not ex x be object st x in X & x in x1 by TARSKI:3,A15;
        reconsider x1 as Element of X by A16;
        the Element of G(x1) in Y1 by A16;
        hence thesis;
      end;then
      consider Z being set such that
A1:   Z in Y1 & for y being set st y in Y1 holds y c= Z
        by FINSET_1:12,A0,A2,A19;
A4:   X c= Z
    proof
      let x be object;
      assume
A8:   x in X;then
      the Element of G(x) in Y1;then
A9:   the Element of G(x) c= Z by A1;
      G(x) is non empty by A8,A18;then
      the Element of G(x) in G(x);then
      consider y3 be Element of Y such that
A10:  y3 = the Element of G(x) & x in y3;
      thus x in Z by A10,A9;
    end;
    consider x be Element of X such that
A6: Z = the Element of G(x) & x in X by A1;
     G(x) is non empty by A6,A18;then
     Z in G(x) by A6;then
     consider y be Element of Y such that
U1:  y = Z & x in y;
     thus ex Z be set st X c= Z & Z in Y by A4,A0,U1;
   end;
 end;
