reserve x for set;
reserve a, b, c, d, e for Real;
reserve m, n, m1, m2 for Nat;
reserve k, l for Integer;
reserve p for Rational;

theorem
  a<=b & (0<=a & n>=1 or n is odd) implies n-root a <= n-root b
proof
  assume that
A1: a<=b and
A2: 0<=a & n>=1 or n is odd;
A3: now
    let a,b,n;
    assume that
A4: 0<=a & n>=1 and
A5: a<=b;
 n -Root a <= n -Root b by A4,A5,PREPOWER:27;
then  n -Root a <= n-root b by A4,A5,Def1;
    hence n-root a <= n-root b by A4,Def1;
  end;
 now
    assume
A6: n is odd;
    then
A7: n>=1 by ABIAN:12;
 now per cases;
      suppose
    a>=0;
        hence thesis by A1,A3,A7;
      end;
      suppose
A8:    a<0;
    now per cases;
          suppose
        b>=0;
then A9:        n-root b >= 0 by A7,Th7;
        n-root (-a) >= 0 by A7,A8,Th7;
then         - n-root (-a) <= -0;
            hence thesis by A6,A9,Th10;
          end;
          suppose
A10:        b<0;
        -a>=-b by A1,XREAL_1:24;
then         n-root (-a) >= n-root (-b) by A3,A7,A10;
then         - n-root (-a) <= - n-root (-b) by XREAL_1:24;
then         n-root a <= - n-root (-b) by A6,Th10;
            hence thesis by A6,Th10;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  hence thesis by A1,A2,A3;
end;
