reserve i,j,x,y for object,
  f,g for Function;
reserve T,T1 for finite Tree,
  t,p for Element of T,
  t1 for Element of T1;

theorem
  for T being finite Tree, p being Element of T st p <> {} holds
  card (T | p) < card T
proof
  let T be finite Tree, p be Element of T;
  reconsider p9 = p as Element of NAT* by FINSEQ_1:def 11;
  set X = { p9^n where n is Element of NAT*: n in T|p };
A1: T|p,X are_equipotent
  proof
    deffunc F(Element of T|p) = p9^$1;
    consider f being Function such that
A2: dom f = T|p and
A3: for n being Element of T|p holds f.n = F(n) from FUNCT_1:sch 4;
    take f;
    thus f is one-to-one
    proof
      let x,y be object such that
A4:   x in dom f & y in dom f and
A5:   f.x = f.y;
      reconsider m = x, n = y as Element of T|p by A2,A4;
      p9^m = f.n by A3,A5
        .= p9^n by A3;
      hence thesis by FINSEQ_1:33;
    end;
    thus dom f = T|p by A2;
    thus rng f c= X
    proof
      let i be object;
      assume i in rng f;
      then consider n being object such that
A6:   n in dom f and
A7:   i = f.n by FUNCT_1:def 3;
      T|p c= NAT* by TREES_1:def 3;
      then reconsider n as Element of NAT* by A2,A6;
      f.n = p9^n by A2,A3,A6;
      hence thesis by A2,A6,A7;
    end;
    let i be object;
    assume i in X;
    then consider n being Element of NAT* such that
A8: i = p9^n and
A9: n in T|p;
    reconsider n as Element of T|p by A9;
    i = f.n by A3,A8;
    hence thesis by A2,FUNCT_1:def 3;
  end;
  then reconsider X as finite set by CARD_1:38;
A10: card X = card(T|p) by A1,CARD_1:5;
  assume
A11: p <> {};
A12: X <> T
  proof
    assume X = T;
    then {} in X by TREES_1:22;
    then ex n being Element of NAT* st {} = p9^n & n in T|p;
    hence contradiction by A11;
  end;
  X c= T
  proof
    let i be object;
    assume i in X;
    then ex n being Element of NAT* st i = p9^n & n in T|p;
    hence thesis by TREES_1:def 6;
  end;
  then X c< T by A12;
  hence thesis by A10,CARD_2:48;
end;
