reserve T for TopStruct;
reserve GX for TopSpace;

theorem Th16:
  for A being Subset of GX ex F being Subset-Family of GX st (for
  C being Subset of GX holds C in F iff C is closed & A c= C) & Cl A = meet F
proof
  let A be Subset of GX;
  defpred Q[set] means ex C1 being Subset of GX st C1 = $1 & C1 is closed & A
  c= $1;
  consider F9 being Subset-Family of GX such that
A1: for C being Subset of GX holds C in F9 iff Q[C] from SUBSET_1:sch 3;
  take F=F9;
  thus for C being Subset of GX holds C in F iff C is closed & A c= C
  proof
    let C be Subset of GX;
    thus C in F implies C is closed & A c= C
    proof
      assume C in F;
      then ex C1 being Subset of GX st C1 = C & C1 is closed & A c= C by A1;
      hence thesis;
    end;
    thus thesis by A1;
  end;
  A c= [#]GX;
  then
A2: F <> {} by A1;
  for p being object holds p in Cl A iff p in meet F
  proof
    let p be object;
A3: now
      assume
A4:   p in meet F;
      now
        let C be Subset of GX;
        assume C is closed & A c= C;
        then C in F by A1;
        hence p in C by A4,SETFAM_1:def 1;
      end;
      hence p in Cl A by A4,Th15;
    end;
    now
      assume
A5:   p in Cl A;
      now
        let C be set;
        assume C in F;
        then
        ex C1 being Subset of GX st C1 = C & C1 is closed & A c= C by A1;
        hence p in C by A5,Th15;
      end;
      hence p in meet F by A2,SETFAM_1:def 1;
    end;
    hence thesis by A3;
  end;
  hence thesis by TARSKI:2;
end;
