reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th16:
  Af is non empty implies (center_of_mass V).Af in conv Af
  proof
    assume Af is non empty;
    then reconsider a=Af as non empty finite Subset of V;
    consider L be Linear_Combination of Af such that
    A1: Sum L=1/card a*Sum a and
    A2: sum L=1/card a*card a and
    A3: L=(ZeroLC V)+*(Af-->1/card a) by Th15;
    A4: dom(Af-->1/card a)=Af;
    A5: 0<=L.v
    proof
      per cases;
      suppose A6: v in Af;
        then L.v=(Af-->1/card a).v by A3,A4,FUNCT_4:13
        .=1/card a by A6,FUNCOP_1:7;
        hence thesis;
      end;
      suppose not v in Af;
        then L.v=(ZeroLC V).v by A3,A4,FUNCT_4:11
        .=0 by RLVECT_2:20;
        hence thesis;
      end;
    end;
    sum L=1 by A2,XCMPLX_1:87;
    then A7: L is convex by A5,RLAFFIN1:62;
    then L in ConvexComb(V) by CONVEX3:def 1;
    then Sum L in {Sum K where K is Convex_Combination of a:K in ConvexComb(V)}
      by A7;
    then Sum L in conv Af by CONVEX3:5;
    hence thesis by A1,Def2;
  end;
