reserve n for Nat,
  a,b,c,d for Real,
  s for Real_Sequence;

theorem
  (for n holds s.n = ((1/3)|^n+3|^n)|^2) implies for n holds
  Partial_Sums(s).n = -(1/9)|^n/8+9|^(n+1)/8+2*n+3
proof
  defpred X[Nat] means Partial_Sums(s).$1 =-(1/9)|^$1/8+9|^($1 +1)/8+2*$1+3;
  assume
A1: for n holds s.n = ((1/3)|^n+3|^n)|^2;
A2: for n st X[n] holds X[n+1]
  proof
    let n;
    assume Partial_Sums(s).n =-(1/9)|^n/8+9|^(n+1)/8+2*n+3;
    then Partial_Sums(s).(n+1) =-(1/9)|^n/8+9|^(n+1)/8+2*n+3+s.(n+1) by
SERIES_1:def 1
      .=-(1/9)|^n/8+9|^(n+1)/8+2*n+3+(((1/3)|^(n+1)+3|^(n+1))|^2) by A1
      .=-(1/9)|^n/8+9|^(n+1)/8+2*n+3+((1/9)|^(n+1)+9|^(n+1)+2) by Lm3
      .=-(1/9)|^n/8+(1/9)|^(n+1)+9|^(n+1)/8+9|^(n+1)+2*(n+1)+3
      .=-(1/9)|^n/8+(1/9)|^n*(1/9)+9|^(n+1)/8+9|^(n+1)+2*(n+1)+3 by NEWTON:6
      .=-((1/9)|^n*(1/9))/8+9|^(n+1)/8+9|^(n+1)+2*(n+1)+3
      .=-(1/9)|^(n+1)/8+9|^(n+1)/8+9|^(n+1)+2*(n+1)+3 by NEWTON:6
      .=-(1/9)|^(n+1)/8+(9|^(n+1)*9)/8+2*(n+1)+3
      .=-(1/9)|^(n+1)/8+9|^(n+1+1)/8+2*(n+1)+3 by NEWTON:6;
    hence thesis;
  end;
  Partial_Sums(s).0 = s.0 by SERIES_1:def 1
    .=((1/3)|^0+3|^0)|^2 by A1
    .=(1+3|^0)|^2 by NEWTON:4
    .=(1+1)|^2 by NEWTON:4
    .=-1/8+9/8+2*0+3 by Lm1
    .=-(1/9)|^0/8+9/8+2*0+3 by NEWTON:4
    .=-(1/9)|^0/8+9|^(0+1)/8+2*0+3;
  then
A3: X[0];
  for n holds X[n] from NAT_1:sch 2(A3,A2);
  hence thesis;
end;
