reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th16:
  card (--X) c= card X
proof
  defpred P[object,object] means for x st x=$1 holds $2 = -x;
  A1:o in --X implies ex u being object st P[o,u]
  proof
    assume o in --X;
    then consider x such that
    A2: x in X & o = -x by Def4;
    take x;
    let y;
    thus thesis by A2;
  end;
  consider f be Function such that
  A3:dom f = --X and
  A4: for o being object st o in --X holds P[o,f.o] from CLASSES1:sch 1(A1);
  A5:rng f c= X
  proof
    let y be object;
    assume y in rng f;
    then consider x be object such that
    A6: x in dom f & f.x=y by FUNCT_1:def 3;
    consider z be Surreal such that
    A7: z in X & x = -z by A3,A6,Def4;
    f.x = - -z =z by A6,A7,A3,A4;
    hence thesis by A7,A6;
  end;
  f is one-to-one
  proof
    let x1,x2 be object such that A8: x1 in dom f & x2 in dom f & f.x1 = f.x2;
    consider y1 be Surreal such that
    A9:y1 in X & x1 = -y1 by A8,A3,Def4;
    consider y2 be Surreal such that
    A10:   y2 in X & x2 = -y2 by A8,A3,Def4;
    f.x1 = - -y1 =y1 & f.x2 = - -y2 =y2 by A10,A9,A3,A8,A4;
    hence thesis by A8,A9,A10;
  end;
  hence thesis by CARD_1:10,A3,A5;
end;
