reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th16:
  for P being Subset of T holds P is finite implies P is bounded
proof
  let P be Subset of T;
  defpred P[set] means ex X being Subset of T st X = $1 & X is bounded;
  {}T is bounded;
  then
A1: P[{}];
A2: for x,B being set st x in P & B c= P & P[B] holds P[B \/ {x}]
  proof
    let x,B be set such that
A3: x in P and
    B c= P and
A4: P[B];
    reconsider x as Element of T by A3;
    reconsider W = {x} as Subset of T;
    consider X being Subset of T such that
A5: X = B & X is bounded by A4;
A6: W is bounded by Th15;
    ex Y being Subset of T st Y = B \/ {x} & Y is bounded
    proof
      take X \/ W;
      thus thesis by A5,A6,Th13;
    end;
    hence thesis;
  end;
  assume
A7: P is finite;
  P[P] from FINSET_1:sch 2(A7,A1,A2);
  hence thesis;
end;
