reserve T,T1,T2 for TopSpace,
  A,B for Subset of T,
  F for Subset of T|A,
  G,G1, G2 for Subset-Family of T,
  U,W for open Subset of T|A,
  p for Point of T|A,
  n for Nat,
  I for Integer;
reserve Af for finite-ind Subset of T,
  Tf for finite-ind TopSpace;

theorem Th16:
  ind Tf <= n iff for p be Point of Tf,U be open Subset of Tf st p
in U ex W be open Subset of Tf st p in W & W c= U & Fr W is finite-ind & ind Fr
  W <= n-1
proof
  set CT=[#]Tf;
  set TT=Tf|CT;
A1: [#]TT=CT by PRE_TOPC:def 5;
  Tf is SubSpace of Tf by TSEP_1:2;
  then
A2: the TopStruct of Tf=the TopStruct of TT by A1,TSEP_1:5;
A3: CT is finite-ind by Def4;
  hereby
    assume
A4: ind Tf<=n;
    let p be Point of Tf,U be open Subset of Tf such that
A5: p in U;
    reconsider p9=p as Point of TT by A1;
    U in the topology of Tf by PRE_TOPC:def 2;
    then reconsider U9=U as open Subset of TT by A2,PRE_TOPC:def 2;
    consider W9 be open Subset of TT such that
A6: p9 in W9 & W9 c=U9 and
A7: Fr W9 is finite-ind & ind Fr W9<=n-1 by A3,A4,A5,Th9;
    W9 in the topology of TT by PRE_TOPC:def 2;
    then reconsider W=W9 as open Subset of Tf by A2,PRE_TOPC:def 2;
    Tf is non empty by A5;
    then Cl W=Cl W9 & Int W=Int W9 by A1,TOPS_3:54;
    then
A8: Fr W=Cl W9\Int W9 by TOPGEN_1:8
      .=Fr W9 by TOPGEN_1:8;
    take W;
    Fr W9 in (Seq_of_ind TT).n by A7,Th7;
    then
A9: Fr W in (Seq_of_ind Tf).n by A8,Th3;
    then Fr W is finite-ind;
    hence p in W & W c=U & Fr W is finite-ind & ind Fr W<=n-1 by A6,A9,Th7;
  end;
  assume
A10: for p be Point of Tf,U be open Subset of Tf st p in U ex W be open
  Subset of Tf st p in W & W c=U & Fr W is finite-ind & ind Fr W<=n-1;
  now
    let p9 be Point of TT,U9 be open Subset of TT such that
A11: p9 in U9;
    reconsider p=p9 as Point of Tf by A1;
    U9 in the topology of TT by PRE_TOPC:def 2;
    then reconsider U=U9 as open Subset of Tf by A2,PRE_TOPC:def 2;
    consider W be open Subset of Tf such that
A12: p in W & W c=U and
A13: Fr W is finite-ind & ind Fr W<=n-1 by A10,A11;
    W in the topology of Tf by PRE_TOPC:def 2;
    then reconsider W9=W as open Subset of TT by A2,PRE_TOPC:def 2;
    Tf is non empty by A11;
    then Cl W=Cl W9 & Int W=Int W9 by A1,TOPS_3:54;
    then
A14: Fr W=Cl W9\Int W9 by TOPGEN_1:8
      .=Fr W9 by TOPGEN_1:8;
    take W9;
    Fr W in (Seq_of_ind Tf).n by A13,Th7;
    then
A15: Fr W9 in (Seq_of_ind TT).n by A14,Th3;
    then Fr W9 is finite-ind;
    hence
    p9 in W9 & W9 c=U9 & Fr W9 is finite-ind & ind Fr W9<=n-1 by A12,A15,Th7;
  end;
  hence thesis by A3,Th9;
end;
