
theorem  :: p. 100, Remark 1.4 (vii)
  for T being non empty transitive reflexive TopRelStr st
  the topology of T = { S where S is Subset of T: S is property(S)}
  holds T is TopSpace-like
proof
  let T be non empty transitive reflexive TopRelStr such that
A1: the topology of T = { S where S is Subset of T: S is property(S)};
  [#]T is property(S) by Lm2;
  hence the carrier of T in the topology of T by A1;
  hereby
    let a be Subset-Family of T such that
A2: a c= the topology of T;
    union a is property(S)
    proof
      let D be non empty directed Subset of T;
      assume sup D in union a;
      then consider x being set such that
A3:   sup D in x and
A4:   x in a by TARSKI:def 4;
      x in the topology of T by A2,A4;
      then consider X being Subset of T such that
A5:   x = X and
A6:   X is property(S) by A1;
      consider y being Element of T such that
A7:   y in D and
A8:   for x being Element of T st x in D & x >=
      y holds x in X by A3,A5,A6;
      take y;
      thus y in D by A7;
      let u be Element of T;
      assume that
A9:   u in D and
A10:  u >= y;
      u in X by A8,A9,A10;
      hence thesis by A4,A5,TARSKI:def 4;
    end;
    hence union a in the topology of T by A1;
  end;
  let a,b be Subset of T;
  assume a in the topology of T;
  then consider A being Subset of T such that
A11: a = A and
A12: A is property(S) by A1;
  assume b in the topology of T;
  then consider B being Subset of T such that
A13: b = B and
A14: B is property(S) by A1;
  A /\ B is property(S)
  proof
    let D be non empty directed Subset of T;
    assume
A15: sup D in A /\ B;
    then sup D in A by XBOOLE_0:def 4;
    then consider x being Element of T such that
A16: x in D and
A17: for z being Element of T st z in D & z >= x holds z in A by A12;
    sup D in B by A15,XBOOLE_0:def 4;
    then consider y being Element of T such that
A18: y in D and
A19: for z being Element of T st z in D & z >= y holds z in B by A14;
    consider z being Element of T such that
A20: z in D and
A21: x <= z and
A22: y <= z by A16,A18,WAYBEL_0:def 1;
    take z;
    thus z in D by A20;
    let u be Element of T such that
A23: u in D;
    assume
A24: u >= z;
    then u >= x by A21,YELLOW_0:def 2;
    then
A25: u in A by A17,A23;
    u >= y by A22,A24,YELLOW_0:def 2;
    then u in B by A19,A23;
    hence thesis by A25,XBOOLE_0:def 4;
  end;
  hence thesis by A1,A11,A13;
end;
